core/btrfs-progs/PKGBUILD

pkgname=btrfs-progs
pkgver=4.7
pkgrel=2
pkgdesc='Btrfs filesystem utilities'
arch=('x86_64')
depends=('glibc' 'util-linux' 'e2fsprogs' 'lzo2' 'zlib')
makedepends=('git' 'asciidoc' 'xmlto')
url='http://btrfs.wiki.kernel.org/'
replaces=('btrfs-progs-unstable')
conflicts=('btrfs-progs-unstable')
provides=('btrfs-progs-unstable')
license=('GPL2')
source=("git://git.kernel.org/pub/scm/linux/kernel/git/kdave/$pkgname.git#tag=v$pkgver"
        'initcpio-install-btrfs'
        'initcpio-hook-btrfs'
        'btrfs-scrub@.service'
        'btrfs-scrub@.timer')
install=btrfs-progs.install
options=(!staticlibs)
md5sums=('SKIP'
         '7241ba3a4286d08da0d50b7176941112'
         'b09688a915a0ec8f40e2f5aacbabc9ad'
         '794b867e09451284c545bae112aa0cfd'
         'a290e0ab88b7b4675cd20f5a2befc8cb')

build() {
   cd $pkgname
   ./autogen.sh
   ./configure --prefix=/usr
   make
}

check() {
   cd $pkgname
   ./btrfs filesystem show
}

package() {
   cd $pkgname

   make DESTDIR=${pkgdir} prefix=/usr install

   # install bash completion (FS#44618)
   install -Dm644 btrfs-completion "$pkgdir/usr/share/bash-completion/completions/btrfs"

   # install mkinitcpio hooks
   cd "$srcdir"
   install -Dm644 initcpio-install-btrfs "$pkgdir/usr/lib/initcpio/install/btrfs"
   install -Dm644 initcpio-hook-btrfs    "$pkgdir/usr/lib/initcpio/hooks/btrfs"

   # install scrub service/timer
   install -Dm644 btrfs-scrub@.service "$pkgdir/usr/lib/systemd/system/btrfs-scrub@.service"
   install -Dm644 btrfs-scrub@.timer   "$pkgdir/usr/lib/systemd/system/btrfs-scrub@.timer"
}

# vim:set ts=2 sw=2 ft=sh et: