core/qt5-webkit/PKGBUILD

# maintainer abveritas@chakra-project.org

pkgname=qt5-webkit
pkgver=5.0.1
_pkgver=5.0.1
pkgrel=1
pkgdesc=('A cross-platform application and UI framework, QtWebkit files')
arch=('x86_64')
url='http://qt.nokia.com/'
license=('GPL3' 'LGPL')
depends=('qt5-declarative' 'icu' 'libxslt' 'libxcomposite' 'gstreamer0.10' 'gstreamer0.10-base'
         'gstreamer0.10-base-plugins' 'gstreamer0.10-good-plugins' 'gstreamer0.10-bad-plugins'
         'gstreamer0.10-ffmpeg' 'gstreamer0.10-ugly-plugins')
makedepends=('gperf' 'sqlite3' 'fontconfig' 'perl' 'python2' 'mesa' 'ruby' 'systemd')
options=('!libtool')
groups=('qt5')
_pkgfqn="qtwebkit-opensource-src-${_pkgver}"
source=("http://origin.releases.qt-project.org/qt5/${_pkgver}/submodules_tar/qtwebkit-opensource-src-${_pkgver}.tar.xz")
md5sums=('8210ea90902c4ec526e1e5f7e719ad57')

build() {
	cd $srcdir/$_pkgfqn
	
	export QTDIR=/usr
	Tools/Scripts/build-webkit --qt \
	                    --qmake=/usr/lib/qt5/bin/qmake \
	                    --install-libs=/usr/lib/qt5 \
	                    --release \
	                    --qmakearg="WEBKIT_CONFIG-=build_test_npapi" \
	                    --qmakearg="WEBKIT_CONFIG-=build_tests" \
	                    --qmakearg="WEBKIT_CONFIG-=have_qttestsupport" \
	                    --qmakearg="WEBKIT_CONFIG-=build_minibrowser"
}

package() {
    cd $srcdir/$_pkgfqn
    mkdir -p ${pkgdir}/usr/lib/qt5/plugins/webkit
    mkdir -p ${pkgdir}/usr/lib/qt5/bin
    make INSTALL_ROOT="${pkgdir}" -C WebKitBuild/Release install
    
    mkdir -p ${pkgdir}/usr/bin
    for i in $(ls ${pkgdir}/usr/lib/qt5/bin); do
        ln -s /usr/lib/qt5/bin/${i} ${pkgdir}/usr/bin/${i}-qt5
    done
}