core/plasma-desktop/PKGBUILD

#contributions from Arch: https://projects.archlinux.org/svntogit/packages.git/tree/trunk?h=packages/plasma-desktop
source ../plasma.conf

pkgname=plasma-desktop
pkgver=${PVersion}
pkgrel=1
pkgdesc='KDE Plasma Desktop'
arch=('x86_64')
url='https://www.kde.org/workspaces/plasmadesktop/'
license=('LGPL')
depends=('qt5-graphicaleffects' 'powerdevil' 'polkit-kde-agent' 'libcanberra'
         'kwin' 'kpeople' 'libusb-compat' 'libxkbfile' 'kmenuedit' 'systemsettings' 'ksysguard' 'breeze' 'krunner' 'baloo' 'kfilemetadata' 'graphite' 'kactivities-stats'
         #sddm can be removed as a dependency in the future, only added here to automate the switch to Plasma 5
         'sddm-kcm')
makedepends=('extra-cmake-modules' 'kdoctools' 'boost' 'xf86-input-synaptics' 'xorg-server-devel' 'xf86-input-evdev')
optdepends=('plasma-nm: Network manager applet'
            'xf86-input-synaptics: Manage touchpad')
checkdepends=("cmake")
replaces=('kde-workspace')
conflicts=('kde-workspace')
groups=('plasma')
options=("debug")
source=("${PServer}/${pkgver}/${pkgname}-${PVersion}.tar.xz"{,.sig})
sha256sums=( $(getSum ${pkgname}) 
             'SKIP' )
source+=( chakra_defaultPanel.patch::https://bugsfiles.kde.org/attachment.cgi?id=102600 )
sha256sums+=( 'af2856ae7904726e6e8cfb3616a51f82fbfee10dc7edc85b579be684601a554c' )
validpgpkeys=(${Pvalidpgpkeys})
install=${pkgname}.install

prepare() {
  mkdir -p build
 
  cd ${pkgname}-${pkgver} 
  # apply custom patch to change from taskmanager to icontasks
  patch -Np1 -i "$srcdir/chakra_defaultPanel.patch"
}

build() {
  cd build
  cmake_kf5 ../${pkgname}-${pkgver}
  make
}

package() {
  cd build
  make DESTDIR="${pkgdir}" install
}