core/python-lxml/PKGBUILD

pkgbase=python-lxml
pkgname=('python3-lxml' 'python2-lxml' 'python-lxml-docs')
pkgver=4.1.0
pkgrel=1
arch=('x86_64')
license=('BSD' 'custom')
url="http://lxml.de/"
makedepends=('python3' 'python3-setuptools' 'python2' 'python2-setuptools' 'libxslt'
             'python3-cssselect' 'python2-cssselect' 'python3-beautifulsoup4' 'python2-beautifulsoup4')
source=(https://pypi.io/packages/source/l/lxml/lxml-${pkgver}.tar.gz)
md5sums=('247580bd5d942872bd972ad0086e5cbf')

prepare() {
  cp -a lxml-$pkgver{,-py2}

  # Setting LC_CTYPE to workaround encoding issue
  export LC_CTYPE=en_US.UTF-8
}

build() {
  cd "$srcdir"/lxml-$pkgver
  python3 setup.py build

  cd "$srcdir"/lxml-$pkgver-py2
  python2 setup.py build
}

package_python3-lxml() {
  pkgdesc="Python3 binding for the libxml2 and libxslt libraries"
  depends=('python3' 'libxslt')
  optdepends=('python3-beautifulsoup4: support for beautifulsoup parser to parse not well formed HTML'
              'python3-cssselect: support for cssselect'
              'python3-html5lib: support for html5lib parser'
              'python-lxml-docs: offline docs')

  cd lxml-$pkgver
  python3 setup.py install --root="$pkgdir" --skip-build --optimize=1
  
  install -Dm644 LICENSES.txt \
    "$pkgdir"/usr/share/licenses/$pkgname/LICENSE
  install -Dm644 doc/licenses/BSD.txt \
    "$pkgdir"/usr/share/licenses/$pkgname/BSD.txt
  install -Dm644 doc/licenses/elementtree.txt \
    "$pkgdir"/usr/share/licenses/$pkgname/elementtree.txt
}

package_python2-lxml() {
  pkgdesc="Python2 binding for the libxml2 and libxslt libraries"
  depends=('python2' 'libxslt')
  optdepends=('python2-beautifulsoup4: support for beautifulsoup parser to parse not well formed HTML'
              'python2-cssselect: support for cssselect'
              'python2-html5lib: support for html5lib parser'
              'python-lxml-docs: offline docs')

  cd lxml-$pkgver-py2
  python2 setup.py install --root="$pkgdir" --skip-build --optimize=1
 
  install -Dm644 LICENSES.txt \
    "$pkgdir"/usr/share/licenses/$pkgname/LICENSE
  install -Dm644 doc/licenses/BSD.txt \
    "$pkgdir"/usr/share/licenses/$pkgname/BSD.txt
  install -Dm644 doc/licenses/elementtree.txt \
    "$pkgdir"/usr/share/licenses/$pkgname/elementtree.txt
}

package_python-lxml-docs() {
  pkgdesc="Python binding for the libxml2 and libxslt libraries (docs)"
  options=('docs')

  cd lxml-$pkgver
  install -d "$pkgdir"/usr/share/doc/$pkgbase
  cp -r doc/html "$pkgdir"/usr/share/doc/$pkgbase

  install -Dm644 LICENSES.txt \
    "$pkgdir"/usr/share/licenses/$pkgname/LICENSE
  install -Dm644 doc/licenses/BSD.txt \
    "$pkgdir"/usr/share/licenses/$pkgname/BSD.txt
  install -Dm644 doc/licenses/elementtree.txt \
    "$pkgdir"/usr/share/licenses/$pkgname/elementtree.txt
}