core/breeze/PKGBUILD

# Contributions from Arch: https://projects.archlinux.org/svntogit/packages.git/tree/trunk?h=packages/breeze
source ../plasma.conf

pkgbase=breeze
pkgname=('breeze' 'breeze-kde4')
pkgver=${PSubVersion}
pkgrel=1
pkgdesc='Artwork, styles and assets for the Breeze visual style for the Plasma Desktop'
arch=('x86_64')
url='https://projects.kde.org/projects/kde/workspace/breeze'
license=('LGPL')
depends=()
makedepends=('extra-cmake-modules' 'frameworkintegration' 'kdecoration' 'kdelibs' 'automoc4')
options=("debug")
source=("${PServer}/${pkgver}/${pkgname}-${pkgver}.tar.xz")
sha256sums=( $(getSum ${pkgname}))

prepare() {
  mkdir -p build{,-kde4}
}

build() {
  cd build
  cmake_kf5 ../${pkgbase}-${PSubVersion}
  make

  cd ../build-kde4
  cmake ../${pkgbase}-${PSubVersion} \
    -DCMAKE_BUILD_TYPE=Release \
    -DCMAKE_INSTALL_PREFIX=/usr \
    -DUSE_KDE4=ON \
    -DBUILD_TESTING=OFF
  make
}

package_breeze() {
  depends=('frameworkintegration' 'kdecoration')
  pkgdesc='Artwork, styles and assets for the Breeze visual style for the Plasma Desktop'
  optdepends=('breeze-kde4: Breeze widget style for KDE4 applications'
              'oxygen-icons: fallback icon theme')
  groups=('plasma')

  cd build
  make DESTDIR="${pkgdir}" install

  # make QtCurve preset and color scheme available for KDE4 too
  install -d "$pkgdir"/usr/share/apps/{QtCurve,color-schemes}
  ln -s /usr/share/QtCurve/Breeze.qtcurve "$pkgdir"/usr/share/apps/QtCurve/
  ln -s /usr/share/color-schemes/Breeze{,Dark}.colors "$pkgdir"/usr/share/apps/color-schemes/
}

package_breeze-kde4() {
  pkgdesc='Artwork, styles and assets for the Breeze visual style for the KDE4'
  depends=('kdelibs')

  cd build-kde4
  make DESTDIR="${pkgdir}" install

  # needed for pure Qt4 apps
  install -d "$pkgdir"/usr/lib/qt/plugins/styles
  ln -s /usr/lib/kde4/plugins/styles/breeze.so "$pkgdir"/usr/lib/qt/plugins/styles
}