core/udisks2/PKGBUILD

pkgname=udisks2
pkgver=2.7.7
pkgrel=1
pkgdesc="Disk Management Service"
arch=('x86_64')
url="http://www.freedesktop.org/wiki/Software/udisks"
license=('GPL2')
depends=('glib2' 'systemd' 'polkit' 'libatasmart' 'util-linux' 'libgudev' 'libblockdev')
makedepends=('intltool' 'docbook-xsl' 'gobject-introspection' 'python2' 'gnome-common' 'gtk-doc' 'libiscsi')
optdepends=('parted: partition management'
            'gptfdisk: GUID partition table support'
            'ntfs-3g: NTFS filesystem management support'
            'dosfstools: VFAT filesystem management support'
            'libiscsi: iSCSI support')
source=("https://github.com/storaged-project/udisks/archive/udisks-$pkgver.tar.gz")
sha512sums=('6e69a4d81ae9401deed7547f537456778f17718a35ecaf69f7636b0aa41d5ad62fb294440f23f4dfd089557b70bc154144e8317a505eaabc639b54e6b70e06e0')

prepare() {
  sed -e 's/AC_MSG_ERROR(\[libstoragemgmt/AC_MSG_WARN([libstoragemgmt/' \
      -e 's/AC_MSG_ERROR(\[libconfig/AC_MSG_WARN([libconfig/' \
      -i udisks-udisks-$pkgver/configure.ac
}

build() {
  cd udisks-udisks-$pkgver
  ./autogen.sh --prefix=/usr \
              --sysconfdir=/etc \
              --localstatedir=/var \
              --libexecdir=/usr/lib \
              --with-systemdsystemunitdir=/usr/lib/systemd/system \
              --disable-static 
  make
}

check() {
  cd udisks-udisks-$pkgver
  make check
}

package() {
  cd udisks-udisks-$pkgver
  make DESTDIR="${pkgdir}" install
     bash_completiondir=/usr/share/bash-completion/completions
}