core/ndiswrapper-lts/PKGBUILD

# Maintainer: Neophytos Kolokotronis <tetris4 AT gmail DOT com>
# contributor: abveritas@chakra-project.org

# Find the kernel name inside the chroot
_extramodules=extramodules-3.2-lts
_kver="$(cat /lib/modules/${_extramodules}/version)"

pkgname=ndiswrapper-lts
_pkgname=ndiswrapper
pkgver=1.59
pkgrel=2
pkgdesc="Module for NDIS (Windows Network Drivers) drivers supplied by vendors. For linux-testing."
license=('GPL')
arch=('x86_64')
url="http://ndiswrapper.sourceforge.net"
install="ndiswrapper.install"
depends=('linux-lts>=3.2' 'linux-lts<3.4')
makedepends=('linux-lts-headers')
source=("http://downloads.sourceforge.net/sourceforge/ndiswrapper/ndiswrapper-$pkgver.tar.gz")
md5sums=('e26a7213468ccd6b0bb4c211c7aadeaa')

build() {
  cd "$srcdir/$_pkgname-$pkgver"

  sed -i "/modinfo/s/s/usr\//" driver/Makefile
  
  make KBUILD=/usr/src/linux-$_kver KVERS=$_kver
}

package() {
  cd "$srcdir/$_pkgname-$pkgver"

  make KBUILD=/usr/src/linux-$_kver INST_DIR="lib/modules/$_extramodules" \
    KVERS=$_kver DESTDIR="$pkgdir/" install

  # rm ndiswrapper
  rm -R "$pkgdir/usr" "$pkgdir/sbin"

  gzip "$pkgdir/lib/modules/$_extramodules/$_pkgname.ko"
}