core/plasma-desktop/PKGBUILD

#contributions from Arch: https://projects.archlinux.org/svntogit/packages.git/tree/trunk?h=packages/plasma-desktop
source ../plasma.conf

pkgname=plasma-desktop
pkgver=${PVersion}
pkgrel=1
pkgdesc='KDE Plasma Desktop'
arch=('x86_64')
url='https://www.kde.org/workspaces/plasmadesktop/'
license=('LGPL')
depends=('qt5-graphicaleffects' 'powerdevil' 'polkit-kde-agent-frameworks' 'libcanberra'
         'kwin' 'kpeople' 'libusb-compat' 'libxkbfile' 'kmenuedit' 'systemsettings' 'ksysguard' 'breeze' 'krunner'
         #sddm can be removed as a dependency in the future, only added here to automate the switch to Plasma 5
         'sddm-kcm')
makedepends=('extra-cmake-modules' 'kdoctools' 'boost' 'baloo-kf5' 'xf86-input-synaptics' 'xorg-server-devel')
optdepends=('plasma-nm: Network manager applet'
            'xf86-input-synaptics: Manage touchpad')
checkdepends=("cmake")
provides=("kcm-touchpad-kf5=${pkgver}")
replaces=('kde-workspace' 'kcm-touchpad-kf5<=5.2.0')
conflicts=('kde-workspace' 'kde-baseapps-kdepasswd' 'kcm-touchpad-kf5<=5.2.0')
groups=('plasma')
options=("debug")
source=("${PServer}/${pkgver}/${pkgname}-${PSubVersion}.tar.xz")
sha256sums=( $(getSum ${pkgname}) )
install=${pkgname}.install

prepare() {
  mkdir -p build
}

build() {
  cd build
  cmake_kf5 ../${pkgname}-${pkgver}
  make
}

package() {
  cd build
  make DESTDIR="${pkgdir}" install
}