core/kde-gtk-config/PKGBUILD

# Contributions from Arch: https://projects.archlinux.org/svntogit/packages.git/tree/trunk?h=packages/kde-gtk-config-frameworks

pkgname=kde-gtk-config
pkgver=5.13.0
pkgrel=2
pkgdesc="GTK2 and GTK3 Configuration for KDE"
arch=('x86_64')
url='projects.kde.org/'
license=('LGPL')
depends=(knewstuff kde-cli-tools gtk3 gsettings-desktop-schemas)
makedepends=(extra-cmake-modules gtk2 python3)
optdepends=('gtk2: GTK2 apps support')
groups=('plasma')
options=("debug")
source=("https://download.kde.org/stable/plasma/$pkgver/$pkgname-$pkgver.tar.xz"{,.sig})
sha256sums=('cf432bc3e05da921ee601e0b3652e3ac1a06b8a48a4ddb01f0d1a3c5a595dfd0'
             'SKIP' )
validpgpkeys=('2D1D5B0588357787DE9EE225EC94D18F7F05997E'  # Jonathan Riddell
              '0AAC775BB6437A8D9AF7A3ACFE0784117FBCE11D'  # Bhushan Shah <bshah@kde.org>
              'D07BD8662C56CB291B316EB2F5675605C74E02CF'  # David Edmundson
              '1FA881591C26B276D7A5518EEAAF29B42A678C20') # Marco Martin <notmart@gmail.com>
install=${pkgname}.install

prepare() {
  mkdir -p build
}

build() {
  cd build
  cmake -DCMAKE_BUILD_TYPE=RelWithDebInfo \
        -DCMAKE_INSTALL_PREFIX=/usr \
        -DKDE_INSTALL_LIBDIR=lib \
        -DKDE_INSTALL_SYSCONFDIR=/etc \
        -DKDE_INSTALL_LIBEXECDIR=lib \
        -DUDEV_RULES_INSTALL_DIR=/usr/lib/udev/rules.d \
        -DBUILD_TESTING=OFF \
        -DKDE_INSTALL_USE_QT_SYS_PATHS=ON "$@"
    make
}

package() {
  cd build
  make DESTDIR="${pkgdir}" install
}