core/networkmanager/PKGBUILD

# maintainer: Martín González kote[at]chakra-project[dot]org>

pkgname=networkmanager
_pkgname=NetworkManager
pkgver=1.0.2
pkgrel=3
_pppver=2.4.7
pkgdesc="Network Management daemon"
arch=('x86_64')
license=('GPL')
url="http://www.gnome.org/projects/NetworkManager/"
depends=('dbus-glib' 'iproute2' 'libndp' 'libnl' 'nss' 'polkit' 'systemd' 'libgudev' 'wpa_supplicant' "ppp=${_pppver}" 'dhclient' 'libsoup' 'modemmanager' 'libnewt' 'libteam')
makedepends=('intltool' 'dhclient' 'iptables' 'gobject-introspection' 'rp-pppoe')
optdepends=('dhcpcd: Alternative dhcp support'
            'dnsmasq: connection sharing'
            'bluez: Bluetooth support'
            'openresolv: resolvconf support'
            'ppp: dialup connection support'
            'rp-pppoe: ADSL support'
            'modemmanager: cellular network support')
backup=('etc/NetworkManager/NetworkManager.conf')
install=networkmanager.install
source=("http://ftp.gnome.org/pub/gnome/sources/$_pkgname/${pkgver:0:3}/$_pkgname-$pkgver.tar.xz"
        'NetworkManager.conf' 
        'disable_set_hostname.patch'
        '0001-dns-Fix-falling-back-in-the-resolv.conf-methods.patch')
md5sums=('5a4899f89edcbdd1ac46d2d947e8d6eb'
         '1653159d6634fb62d3a5c548b7a56151'
         '6b5415350c04304a28d29294441a07ae'
         '096f138fc7dae0a8f0af0a8b262251a4')

prepare() {
  cd $_pkgname-$pkgver
  patch -Np1 -i ../disable_set_hostname.patch
  patch -Np1 -i ../0001-dns-Fix-falling-back-in-the-resolv.conf-methods.patch
}

build() {
  cd $_pkgname-$pkgver

  ./configure \
    --prefix=/usr \
    --sysconfdir=/etc \
    --localstatedir=/var \
    --sbindir=/usr/bin \
    --libexecdir=/usr/lib/networkmanager \
    --with-crypto=nss \
    --with-dhclient=/usr/bin/dhclient \
    --with-dhcpcd=/usr/bin/dhcpcd \
    --with-dnsmasq=/usr/bin/dnsmasq \
    --with-iptables=/usr/bin/iptables \
    --with-systemdsystemunitdir=/usr/lib/systemd/system \
    --with-udev-dir=/usr/lib/udev \
    --with-resolvconf=/usr/bin/resolvconf \
    --with-pppd=/usr/bin/pppd \
    --with-pppd-plugin-dir=/usr/lib/pppd/$_pppver \
    --with-pppoe=/usr/bin/pppoe \
    --with-kernel-firmware-dir=/usr/lib/firmware \
    --with-session-tracking=systemd \
    --with-modem-manager-1 \
    --disable-static \
    --enable-more-warnings=no \
    --disable-wimax \
    --enable-modify-system 

  make
}

package() {
  cd $_pkgname-$pkgver
  make DESTDIR="$pkgdir" install

  install -m644 ../NetworkManager.conf "$pkgdir/etc/NetworkManager/"
  install -m755 -d "$pkgdir/etc/NetworkManager/dnsmasq.d"
 
  rm -r "$pkgdir/var/run"  
}