core/modemmanager-qt/PKGBUILD

pkgname=modemmanager-qt
_pkgname=modemmanager-qt
pkgver=5.47.0
pkgrel=1
pkgdesc="Plasma Workspace"
arch=('x86_64')
url='http://projects.kde.org'
license=('LGPL')
depends=('qt5-base' 'networkmanager')
makedepends=("extra-cmake-modules>=${KFECMVersion}" 'kapidox')
checkdepends=("cmake")
provides=("libmm-qt5=${pkgver}")
replaces=("libmm-qt5<=5.2.2")
conflicts=("libmm-qt5<=5.2.2")
groups=('kf5')
options=("debug")
source=("https://download.kde.org/stable/frameworks/${pkgver%.*}/${pkgname}-${pkgver}.tar.xz"{,.sig})
sha256sums=('8b6ab15ce82b7a30b26814178ac33380056ec4398707481aa5ce95cf09d39d03'
            SKIP)
validpgpkeys=(53E6B47B45CEA3E0D5B7457758D0EE648A48B3BB) # David Faure <faure@kde.org>

prepare() {
  mkdir -p build
}

build() {
  cd build
  cmake ../${pkgname}-${pkgver} \
         -DCMAKE_BUILD_TYPE=RelWithDebInfo \
        -DCMAKE_INSTALL_PREFIX=/usr \
        -DKDE_INSTALL_LIBDIR=lib \
        -DKDE_INSTALL_SYSCONFDIR=/etc \
        -DKDE_INSTALL_LIBEXECDIR=lib \
        -DBUILD_TESTING=OFF \
        -DKDE_INSTALL_USE_QT_SYS_PATHS=ON "$@"
  make
}

check() {
  cd build
  make test || return 0
}

package() {
  cd build
  make DESTDIR="${pkgdir}" install
}