core/sonnet/PKGBUILD

# Contributor: Andrea Scarpino <andrea@archlinux.org>


pkgname=sonnet
pkgver=5.47.0
pkgrel=1
pkgdesc='Spelling framework for Qt5'
arch=('x86_64')
url='https://projects.kde.org/projects/frameworks/sonnet'
license=('LGPL')
depends=("qt5-base" 'enchant')
makedepends=("extra-cmake-modules>=${KFECMVersion}" 'qt5-tools')
groups=('kf5')
options=("debug")
source=("https://download.kde.org/stable/frameworks/${pkgver%.*}/${pkgname}-${pkgver}.tar.xz"{,.sig})
sha256sums=('f965f10dc3e1cc0ab810db38fe1be9385c8f505ca84bd87587f2d2f0c3cece92'
            SKIP)
validpgpkeys=(53E6B47B45CEA3E0D5B7457758D0EE648A48B3BB) # David Faure <faure@kde.org>

prepare() {
  mkdir -p build
}

build() {
  cd build
  cmake ../${pkgname}-${pkgver} \
         -DCMAKE_BUILD_TYPE=RelWithDebInfo \
        -DCMAKE_INSTALL_PREFIX=/usr \
        -DKDE_INSTALL_LIBDIR=lib \
        -DKDE_INSTALL_SYSCONFDIR=/etc \
        -DKDE_INSTALL_LIBEXECDIR=lib \
        -DBUILD_TESTING=OFF \
        -DKDE_INSTALL_USE_QT_SYS_PATHS=ON "$@"
  make
}

package() {
  cd build
  make DESTDIR="${pkgdir}" install
}