core/tools-pkg-appset-qt/PKGBUILD

# Maintainer: Phil Miller <philm[at]chakra-project[dot]org>
# Committer: Simone Tobia <simone.tobia at gmail dot com>
# Translators: http://chakra-project.org/bbs/viewtopic.php?pid=29626#p29626

pkgname=appset-qt
pkgver=0.7.1
pkgrel=1
pkgdesc="An advanced and feature rich Package Manager Frontend"
arch=('i686' 'x86_64')
url="http://appset.sourceforge.net/"
license=('GPL2')
depends=('qt>=4.7' 'kde-baseapps-konsole')
optdepends=('ccr: For Community Repository support')
install=${pkgname}.install
source=("http://sourceforge.net/projects/appset/files/appset-qt/0.7/$pkgver/appset-qt-$pkgver-sources.tar.gz"
        "http://chakra-linux.org/sources/$pkgname/appset-qt-oxygen-icons.tar.xz"
        "http://chakra-linux.org/sources/$pkgname/$pkgname-0.7.0-chakra.patch"
        )
md5sums=('83100d84a8735abd3a1cca4f6f1d3197'
         '87f5f278e3fe67ed2cd6165c2835d81b'
         '9b6b473d2a2ff31457f0f6e9fe3d345f')

build() {
  cd $srcdir/$pkgname-$pkgver-sources
  # copy oxygen icons
  cp -v ../*png Qt/AppSet-Qt

  # patch it for Chakra GNU/Linux
  patch -Np1 -i ${startdir}/src/$pkgname-0.7.0-chakra.patch

  # check for updated strings
  cd Qt/AppSet-Qt
  lupdate *.cpp *.ui *.h -ts *.ts
  cd ../AppSetTray-Qt
  lupdate *.cpp *.h -ts *.ts
  cd ../AppSetRepoEditor-Qt
  lupdate *.cpp *.ui *.h -ts *.ts
  cd ../..

  qmake PREFIX=/usr -Wnone

  #localization
  lrelease Qt/AppSet-Qt/*.ts
  lrelease Qt/AppSetTray-Qt/*.ts
  lrelease Qt/AppSetRepoEditor-Qt/*.ts

  make || return 1
}

package() {
    cd $srcdir/$pkgname-$pkgver-sources

    make INSTALL_ROOT="$pkgdir/" install

    #helper daemon
    install -m 755 -d "$pkgdir/etc/rc.d" || return 1
    install -m 755 "$srcdir/$pkgname-$pkgver-sources/AppSetHelper/appset-helper.sh" "$pkgdir/etc/rc.d/appset-helper"
}