core/pypy/PKGBUILD

# Maintainer: Fabian Kosmale <inkane@chakra-project.org>
# Contributor: Daniele Cocca <jmc@chakra-project.org>

pkgname=pypy
pkgver=2.5.0
pkgrel=1
pkgdesc="A Python implementation written in Python, JIT enabled"
arch=('x86_64')
url="http://www.pypy.org/"
license=('custom:MIT')
depends=('libffi')
provides=('python2')
makedepends=('sqlite3' 'python2' 'pypy' 'tk')
optdepends=('openssl: openssl module'
            'expat: pyexpat module'
            'ncurses: ncurses module'
            'zlib: zlib module'
            'bzip2: bz2 module'
            'tk: tk module')
source=("https://bitbucket.org/${pkgname}/${pkgname}/downloads/$pkgname-$pkgver-src.tar.bz2")
options=(!buildflags)
md5sums=('f4700c0af45e986178b36ce91a45136e')

build() {
  cd "${srcdir}"/${pkgname}-${pkgver}-src/pypy/goal

  # here you can boostrap with python if needed
  pypy ../../rpython/bin/rpython -Ojit targetpypystandalone
}

package() {
  cd "${srcdir}"/${pkgname}-${pkgver}-src/pypy/tool/release

  pypy package.py ../../../ pypy pypy-c "${srcdir}"/${pkgname}.tar.bz2

  mkdir -p "${pkgdir}"/opt
  tar x -C "${pkgdir}"/opt -f "${srcdir}"/${pkgname}.tar.bz2

  # Install binary symlink
  install -d -m755 "${pkgdir}/usr/bin"
  ln -sf "/opt/${pkgname}/bin/pypy-c" "${pkgdir}/usr/bin/pypy"
  
  install -Dm644 "${pkgdir}"/opt/pypy/LICENSE "${pkgdir}"/usr/share/licenses/pypy/LICENSE
}