core/foomatic/PKGBUILD

#
# Chakra Packages for Chakra, part of chakra-project.org
#
# maintainer (i686): Phil Miller <philm[at]chakra-project[dog]org>
# maintainer (x86_64): Manuel Tortosa <manutortosa[at]chakra-project[dot]org>

# include global config
source ../_buildscripts/${current_repo}-${_arch}-cfg.conf
 
pkgbase="foomatic"
pkgname=('foomatic-db' 'foomatic-filters' 'foomatic-db-engine' 'foomatic-db-nonfree')
arch=('i686' 'x86_64') # needs to be changed  in the subpackages when makepkg will support it
_snapdate=20100608
_relver=4.0.4
pkgver=${_relver}_${_snapdate}
pkgrel=1
makedepends=('cups>=1.4.2' 'perl' 'libxml2' 'enscript' 'perl' 'net-snmp' 'bash')
source=(http://www.openprinting.org/download/foomatic/$pkgbase-{filters,db-engine}-${_relver}.tar.gz
        http://www.openprinting.org/download/foomatic/$pkgbase-db-4.0-${_snapdate}.tar.gz
        http://www.openprinting.org/download/foomatic/$pkgbase-db-nonfree-${_snapdate}.tar.gz)
url="http://www.linuxprinting.org/foomatic.html"
options=('force' '!emptydirs')
md5sums=('f67fc793ee8d4d076c6671d6e6a72367'  # foomatic-filters-4.0.4.tar.gz
         '675999e0ab8d59ad34a805c378830354'  # foomatic-db-engine-4.0.4.tar.gz
         '07e329f6ff67973108c03c3b9849bf11'  # foomatic-db-4.0-20100608.tar.gz
         'd4a17e93a0d4ce6739dfbc7517c02f3c') # foomatic-db-nonfree-20100608.tar.gz

build() {
 /bin/true
}

package_foomatic-db() {

 pkgdesc="Foomatic - The collected knowledge about printers, drivers, and driver options in XML files, used by foomatic-db-engine to generate PPD files."
# arch=('any')
 license=('GPL' 'custom')
 depends=('perl' 'libxml2')
 replaces=('foomatic-db-ppd' 'foomatic-db-hpijs')
 conflicts=('foomatic-db-ppd' 'foomatic-db-hpijs')
 provides=('foomatic-db-hpijs')

   cd ${srcdir}/${pkgname}-${_snapdate}
   ./configure --prefix=/usr
   make DESTDIR=${pkgdir} install || return 1
   install -v -Dm644 ${srcdir}/${pkgname}-${_snapdate}/COPYING ${pkgdir}/usr/share/licenses/${pkgname}/COPYING || return 1
}

package_foomatic-filters() {

 pkgdesc="Foomatic - Filter scripts used by the printer spoolers to convert the incoming PostScript data into the printer's native format."
# arch=('i686' 'x86_64')
 license=('GPL')
 backup=(etc/foomatic/filter.conf)
 depends=('glibc')
 optdepends=('perl:      for the "beh" Backend End Handler used by cups'
            'net-snmp:  certain (mostly HP) printers need it to work')

#   cd ${srcdir}/${pkgname}-${pkgver}
   cd ${srcdir}/foomatic-filters-${_relver}
   ./configure --prefix=/usr --sysconfdir=/etc
   make || return 1
   make DESTDIR=${pkgdir} install || return 1
}

package_foomatic-db-engine() {

 pkgdesc="Foomatic - Foomatic's database engine generates PPD files from the data in Foomatic's XML database. It also contains scripts to directly generate print queues and handle jobs."
# arch=(i686 x86_64)
 license=('GPL')
 depends=('perl' 'libxml2' 'foomatic-filters' 'bash')

#   cd ${srcdir}/${pkgname}-${pkgver}
   cd ${srcdir}/foomatic-db-engine-${_relver}
    ./configure --prefix=/usr
   make || return 1
   eval `perl -V:archname`
   make DESTDIR=${pkgdir} \
        INSTALLARCHLIB=/usr/lib/perl5/vendor_perl/ \
        INSTALLSITELIB=/usr/lib/perl5/vendor_perl/ \
        INSTALLSITEARCH=/usr/lib/perl5/vendor_perl/ install || return 1
   /usr/bin/find ${pkgdir} -name '.packlist' -delete
   # fix permissions
   chmod 755 ${pkgdir}/usr/lib{,/perl5,/perl5/vendor_perl}
}

package_foomatic-db-nonfree() {

 pkgdesc="Foomatic - database extension consisting of manufacturer-supplied PPD files released under non-free licenses"
# arch=('any')
 license=('custom')
 depends=('perl' 'libxml2' "foomatic-db-engine" 'foomatic-db')

#   cd ${srcdir}/${pkgname}-${_snapdate}
   cd ${srcdir}/foomatic-db-nonfree-${_snapdate}
   ./configure --prefix=/usr
   make DESTDIR=${pkgdir} install || return 1
#   install -Dm644 COPYING ${pkgdir}/usr/share/licenses/${pkgname}/COPYING || return 1
   install -Dm644 COPYING ${pkgdir}/usr/share/licenses/foomatic-db-nonfree/COPYING || return 1
}