core/ndiswrapper/PKGBUILD

# Source global configuration
source ../linux.conf

pkgname=ndiswrapper
_commit=d3ffd3008d4e0d696b0efad2d079b2339dfd9178
pkgver=1.60
pkgrel=6
pkgdesc="Module for NDIS (Windows Network Drivers) drivers supplied by vendors. For linux-testing."
license=('GPL')
arch=('x86_64')
url="http://ndiswrapper.sourceforge.net"
install="ndiswrapper.install"
depends=("linux=${_kernelver}")
makedepends=("linux-headers=${_kernelver}")
provides=("ndiswrapper-utils=$pkgver")
replaces=('ndiswrapper-utils')
conflicts=('ndiswrapper-utils')
makedepends=('linux-headers')
source=("git+https://github.com/pgiri/ndiswrapper.git#commit=$_commit")
sha1sums=('SKIP')

prepare() {
  [ -z "$_kver" ] && error "Could not get kernel version from '/usr/lib/modules/${_extramodules}/version'..." && false
  msg "Found kernel version: $_kver"

  cd "$srcdir/$pkgname/$pkgname"

  sed -i -e 's|strnicmp|strncasecmp|' driver/ndis.c
  sed -i "/modinfo/s/s/usr\//" driver/Makefile
}

build() {
  cd "$srcdir/$pkgname/$pkgname"
  make -C driver KVERS_UNAME=${_kver}
  make -C utils
}

package() {
  cd "$srcdir/$pkgname/$pkgname"

  make sbindir=usr/sbin usrsbindir=usr/bin KBUILD=${_rootOfSourceTree} INST_DIR="usr/lib/modules/$_extramodules" \
        KVERS=$_kver DESTDIR="$pkgdir/" install

  sed -i -e "s/EXTRAMODULES='.*'/EXTRAMODULES='${_extramodules}'/" \
          "${startdir}/ndiswrapper.install"
}