core/tk/PKGBUILD

pkgname=tk
pkgver=8.6.4
pkgrel=2
pkgdesc="A windowing toolkit for use with tcl"
arch=('x86_64')
url="http://tcl.sourceforge.net/"
license=('custom')
depends=("tcl=${pkgver}" 'libxss' 'libxft' 'graphite')
options=('staticlibs')
source=("http://downloads.sourceforge.net/sourceforge/tcl/${pkgname}${pkgver}-src.tar.gz")
sha1sums=('ad24c59ac2e7453d1ed2bad0d7d18a01eabc5226')

build() {
  cd "${srcdir}/${pkgname}${pkgver}/unix"

  ./configure --prefix=/usr \
              --mandir=/usr/share/man \
              --enable-threads \
              --enable-xft \
              --enable-64bit
  
  make
}

package() {
  cd "${srcdir}/${pkgname}${pkgver}/unix"
    
  make INSTALL_ROOT="${pkgdir}" install install-private-headers
  ln -sf "wish8.6" "${pkgdir}/usr/bin/wish"
  ln -sf libtk${pkgver%.*}.so "${pkgdir}/usr/lib/libtk.so"

  # install license
  install -Dm644 license.terms "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE"

  # remove buildroot traces
  sed -e "s#${srcdir}/tk${pkgver}/unix#/usr/lib#" \
      -e "s#${srcdir}/tk${pkgver}#/usr/include#" \
      -i "${pkgdir}/usr/lib/tkConfig.sh"
}