core/r8168/PKGBUILD

_extramodules=extramodules-4.5-CHAKRA
_kernver="$(cat /usr/lib/modules/$_extramodules/version || true)"
_kernelver=4.5.7

pkgname=r8168
pkgver=8.041.00
pkgrel=2
pkgdesc="A kernel module for Realtek 8168 network cards"
url="http://www.realtek.com.tw"
license=("GPL")
arch=('x86_64')
depends=('glibc' "linux=${_kernelver}")
makedepends=("linux-headers=${_kernelver}")
install=$pkgname.install
source=("https://github.com/mtorromeo/r8168/archive/$pkgver/$pkgname-$pkgver.tar.gz"
        'linux-4.5.patch')
sha256sums=('d56f60e4157ccbf8f8717270b1acb391b0a959d9a96c2f0b4a91c683aa8b83a5'
            'e05a4bccf28beecc97db246064a5fe80d1303476b76086bd262c9c8db82b2e6e')

prepare(){
	cd "$pkgname-$pkgver"
	patch -Np1 -i "$srcdir/linux-4.5.patch"
}

build() {
	cd "$srcdir/$pkgname-$pkgver"
	
	make -C /usr/lib/modules/$_kernver/build \
			SUBDIRS="$srcdir/$pkgname-$pkgver/src" \
			EXTRA_CFLAGS="-DCONFIG_R8168_NAPI -DCONFIG_R8168_VLAN" \
			modules
}

package() {
	cd "$srcdir/$pkgname-$pkgver/src"
	install -D -m644 $pkgname.ko "$pkgdir/usr/lib/modules/$_extramodules/$pkgname.ko"
	find "$pkgdir" -name '*.ko' -exec gzip -9 {} \;
        sed -i -e "s/EXTRAMODULES='.*'/EXTRAMODULES='${_extramodules}'/" "${startdir}/$pkgname.install"
}