core/ndiswrapper-lts/PKGBUILD

# Maintainer: Neophytos Kolokotronis <tetris4 AT gmail DOT com>
# contributor: abveritas@chakra-project.org

# Find the kernel name inside the chroot
_extramodules=extramodules-3.2-lts
_kver="$(cat /lib/modules/${_extramodules}/version)"
_kernelver=3.2.63

pkgname=ndiswrapper-lts
_pkgname=ndiswrapper
pkgver=1.59
pkgrel=4
pkgdesc="Module for NDIS (Windows Network Drivers) drivers supplied by vendors. For linux-testing."
license=('GPL')
arch=('x86_64')
url="http://ndiswrapper.sourceforge.net"
install="ndiswrapper.install"
depends=("linux-lts=${_kernelver}")
makedepends=("linux-lts-headers=${_kernelver}")
source=("http://downloads.sourceforge.net/sourceforge/ndiswrapper/ndiswrapper-$pkgver.tar.gz")
md5sums=('e26a7213468ccd6b0bb4c211c7aadeaa')

build() {
  cd "$srcdir/$_pkgname-$pkgver"

  sed -i "/modinfo/s/s/usr\//" driver/Makefile
  
  make KBUILD=/usr/src/linux-$_kver KVERS=$_kver
}

package() {
  cd "$srcdir/$_pkgname-$pkgver"

  make KBUILD=/usr/src/linux-$_kver INST_DIR="usr/lib/modules/$_extramodules" \
    KVERS=$_kver DESTDIR="$pkgdir/" install

  # rm ndiswrapper
  rm -r "$pkgdir/usr/share" "$pkgdir/usr/sbin" "$pkgdir/sbin"

  gzip "$pkgdir/usr/lib/modules/$_extramodules/$_pkgname.ko"
}