core/hspell/PKGBUILD

# Contributor: Tobias Powalowski <tpowa@archlinux.org>

pkgbase=hspell
pkgname=('hspell' 'hunspell-he')
pkgver=1.3
pkgrel=1
arch=('i686' 'x86_64')
license=('GPL')
url="http://www.ivrix.org.il/projects/spell-checker/"
makedepends=('glibc' 'zlib' 'perl' 'hunspell' 'gawk')
options=('!libtool' '!makeflags')
source=(http://hspell.ivrix.org.il/${pkgname}-${pkgver}.tar.gz)
md5sums=('351850c9f6974a709dd092a2d1063e4a')

build() {
  cd "${srcdir}/${pkgname}-${pkgver}"
  ./configure --prefix=/usr --mandir=/usr/share/man \
      --enable-linginfo --enable-fatverb --enable-shared
  make 
  make hunspell
}

package_hspell() {

  pkgdesc="Hebrew spell-checker"
  depends=('glibc' 'zlib' 'perl')

  cd "${srcdir}/${pkgname}-${pkgver}"
  make DESTDIR="${pkgdir}" install

  rm -f ${pkgdir}/usr/lib/libhspell.a
}

package_hunspell-he() {

  pkgdesc="Hebrew hunspell dictionary"
  
  cd "${srcdir}/${pkgbase}-${pkgver}"

  install -dm755 ${pkgdir}/usr/share/hunspell
  install -m644 he.dic ${pkgdir}/usr/share/hunspell/he_IL.dic
  install -m644 he.aff ${pkgdir}/usr/share/hunspell/he_IL.aff

  # the symlinks
  install -dm755 ${pkgdir}/usr/share/myspell/dicts
  pushd $pkgdir/usr/share/myspell/dicts
    for file in $pkgdir/usr/share/hunspell/*; do
      ln -sv /usr/share/hunspell/$(basename $file) .
    done
  popd
}