core/ntp/PKGBUILD

pkgname=ntp
_pkgname=ntp #-dev
_pkgver=4.2.8p10
pkgver=${_pkgver/p/.p}
pkgrel=2
pkgdesc='Network Time Protocol reference implementation'
url="http://www.ntp.org/"
license=('custom')
arch=('x86_64')
depends=('openssl' 'libcap' 'libedit')
makedepends=('perl-html-parser')
backup=('etc/ntp.conf')
options=('!emptydirs')
source=("https://www.eecis.udel.edu/~ntp/ntp_spool/ntp4/${_pkgname}-4.2/${_pkgname}-${_pkgver}.tar.gz"
        'ntp.conf'
        'ntpd.service'
        'ntpdate.service')
sha1sums=('503d68cfd3e6a9354e0e28dd38b39d850b1228b2'
          '76045019df8182c8b759828549dbd957e26c4d6e'
          '0cccca872385e0142888ab48d273fec0669b30a8'
          '059b382d1af0c55202e2d17f2ae065a2cbfec9ee')
install=install

build() {
  cd "${srcdir}/${pkgname}-${_pkgver}"
  
  ./configure --prefix=/usr \
    --libexecdir=/usr/lib \
    --mandir=/usr/share/man \
    --enable-linuxcaps \
    --enable-ntp-signd
    
  make
}

package() {
  cd "${srcdir}/${pkgname}-${_pkgver}"
  
  make DESTDIR="${pkgdir}" install
  
  install -d -o 87 "${pkgdir}/var/lib/ntp"
  install -Dm644 ../ntp.conf "${pkgdir}"/etc/ntp.conf
  install -Dm644 ../ntpd.service "${pkgdir}"/usr/lib/systemd/system/ntpd.service
  install -Dm644 ../ntpdate.service "${pkgdir}"/usr/lib/systemd/system/ntpdate.service
  install -Dm644 COPYRIGHT "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE"

  install -d -o 87 "${pkgdir}"/var/lib/ntp
  echo > "${pkgdir}/var/lib/ntp/.placeholder"
}