core/strigi/PKGBUILD

#
# Chakra Packages for Chakra, part of chakra-project.org
#
# Maintainer: Fabian Kosmale <0inkane@googlemail.com>
# contributor: Giuseppe Calà <jiveaxe@gmail.com>

pkgname=strigi
pkgver=0.7.7
pkgrel=4
pkgdesc="Fast crawling desktop search engine with Qt4 GUI"
arch=('x86_64')
url="http://www.vandenoever.info/software/strigi/"
license=('GPL2')
depends=('bzip2' 'exiv2' 'libxml2' 'boost-libs')
makedepends=('qt' 'cmake' 'pkgconfig' 'boost')
provides=('strigi-git')
replaces=('strigi-git')
conflicts=('strigi-git')
source=("http://chakra-linux.org/sources/${pkgname}/${pkgname}-${pkgver}.tar.bz2"
        'gcc47.patch')
md5sums=('ca0a0fd5c2b99879f6330837aeede996'
         '1acb9b31a4859dc427fc4d387fd8aa2f')
options=('!libtool')

build() {
  pushd ${pkgname}-${pkgver}/strigidaemon
  patch -p1 -i "${srcdir}"/gcc47.patch
  popd

  mkdir build
  cd build
  cmake ../${pkgname}-${pkgver} \
    -DCMAKE_BUILD_TYPE=Release \
    -DCMAKE_INSTALL_PREFIX=/usr \
    -DENABLE_INOTIFY=ON \
    -DENABLE_LOG4CXX=OFF \
    -DENABLE_FAM=OFF \
    -DENABLE_CLUCENE=OFF \
    -DENABLE_CLUCENE_NG=OFF \
    -DENABLE_FFMPEG=OFF
  make
}

package() {
  pushd build/libstreams
  make DESTDIR="${pkgdir}" install
  popd

  pushd build/libstreamanalyzer
  make DESTDIR="${pkgdir}" install
  popd

  pushd build/strigiclient/lib/searchclient/qtdbus
  make DESTDIR="${pkgdir}" install
  popd
  
  pushd build/strigiutils
  make DESTDIR="${pkgdir}" install
  popd
}