core/curl/PKGBUILD

# $Id: PKGBUILD 77510 2010-04-15 02:24:30Z dgriffiths $
# Contributor: Eric Belanger <eric@archlinux.org>
# Contributor: Lucien Immink <l.immink@student.fnt.hvu.nl>
# Maintainer: Daniel J Griffiths <ghost1227@archlinux.us>

pkgname=curl
pkgver=7.21.3
pkgrel=1
pkgdesc="An URL retrival utility and library"
arch=('i686' 'x86_64')
url="http://curl.haxx.se"
license=('MIT')
depends=('zlib' 'openssl' 'bash' 'ca-certificates')
options=('!libtool')
source=("http://curl.haxx.se/download/${pkgname}-${pkgver}.tar.bz2")
md5sums=('5b57fee22090b5c43a6886fdd35af2ce')

build() {
	cd ${srcdir}/${pkgname}-${pkgver}

	./configure \
	    --with-random=/dev/urandom \
	    --prefix=/usr \
	    --mandir=/usr/share/man \
	    --disable-dependency-tracking \
	    --enable-ipv6 \
	    --disable-ldaps \
	    --disable-ldap \
	    --enable-manual \
	    --enable-versioned-symbols \
	    --with-ca-path=/etc/ssl/certs \
	    --without-libidn || return 1
	make || return 1
}

package() {
	cd ${srcdir}/${pkgname}-${pkgver}

	make DESTDIR=${pkgdir} install || return 1
	install -Dm644 COPYING \
		${pkgdir}/usr/share/licenses/${pkgname}/COPYING || return 1
	install -Dm644 docs/libcurl/libcurl.m4 \
		${pkgdir}/usr/share/aclocal/libcurl.m4 || return 1
}