# Contributions from Arch: https://projects.archlinux.org/svntogit/packages.git/tree/trunk?h=packages/xz

pkgname=xz
pkgver=5.2.1
pkgrel=1
pkgdesc='Library and command line tools for XZ and LZMA compressed files'
arch=('x86_64')
url='http://tukaani.org/xz/'
license=('GPL' 'LGPL' 'custom')
depends=('sh')
provides=('lzma' 'lzma-utils' 'xz-utils')
replaces=('lzma' 'lzma-utils' 'xz-utils')
conflicts=('lzma' 'lzma-utils' 'xz-utils')
options=('!libtool')
source=("http://tukaani.org/${pkgname}/${pkgname}-${pkgver}.tar.gz")
md5sums=('3e44c766c3fb4f19e348e646fcd5778a')

build() {
        cd ${srcdir}/${pkgname}-${pkgver}

        ./configure --prefix=/usr \
                --disable-rpath \
                --enable-werror
        make
}

check() {
        cd ${srcdir}/${pkgname}-${pkgver}
        make check
}

package() {
        cd ${srcdir}/${pkgname}-${pkgver}
        make DESTDIR=${pkgdir} install
        install -d -m755 ${pkgdir}/usr/share/licenses/xz/
        ln -sf /usr/share/doc/xz/COPYING ${pkgdir}/usr/share/licenses/xz/
        ln -sf /usr/share/licenses/common/GPL2/license.txt ${pkgdir}/usr/share/doc/xz/COPYING.GPLv2
}