# Arch contributor: https://projects.archlinux.org/svntogit/packages.git/plain/trunk/PKGBUILD?h=packages/libsoxr

pkgname=libsoxr
pkgver=0.1.2
pkgrel=1
pkgdesc='The SoX Resampler library that aims to give fast and high quality results for any constant resampling ratio'
arch=(i686 x86_64) 
url='http://sourceforge.net/p/soxr/wiki/Home/'
license=(GPL)
depends=(gcc-libs)
makedepends=(cmake)
options=(!emptydirs)
source=(http://downloads.sourceforge.net/project/soxr/soxr-$pkgver-Source.tar.xz)
sha1sums=('3b990f91dc8dc08e70626cd5fb90deda0239c211')

build() {
  cd soxr-$pkgver-Source
  cmake \
    -DCMAKE_INSTALL_PREFIX=/usr \
    -DBUILD_EXAMPLES=OFF \
    -DBUILD_SHARED_LIBS=ON \
    -DCMAKE_BUILD_TYPE=Release \
    -DVISIBILITY_HIDDENL=ON \
    -DWITH_AVFFT=ON \
    -DWITH_DOUBLE_PRECISION=ON \
    -DWITH_LSR_BINDINGS=ON \
    -DWITH_OPENMP=ON \
    -DWITH_PFFFT=ON \
    -DWITH_SIMD=ON \
    .
  make
}

check() {
  cd soxr-$pkgver-Source
  make test
}

package() {
  cd soxr-$pkgver-Source
  
  make DESTDIR="$pkgdir" install
  install -Dm644 LICENCE "$pkgdir"/usr/share/licenses/$pkgname/LICENSE
  rm -r "$pkgdir"/usr/share/doc/$pkgname/
}