# Arch Contributor: Felix Yan <felixonmars@archlinux.org>

pkgbase=python-hyperlink
pkgname=('python3-hyperlink' 'python2-hyperlink')
pkgver=17.3.1
pkgrel=1
pkgdesc='A featureful, correct URL for Python'
arch=('any')
license=('BSD')
url='https://github.com/python-hyper/hyperlink'
makedepends=('python3-setuptools' 'python2-setuptools')
checkdepends=('python3-pytest-runner' 'python2-pytest-runner')
source=("$pkgbase-$pkgver.tar.gz::https://github.com/python-hyper/hyperlink/archive/v$pkgver.tar.gz")
sha512sums=('3c7ec4c7686066360130a72345af0257605b76415d58030fbb2e02bc52a58a43ea77455eb4acf9181131ff311f9fe54c7a15b05e7c5093fb24368ccd12e116b2')

prepare() {
  cp -a hyperlink-$pkgver{,-py2}
}

build() {
  cd "$srcdir"/hyperlink-$pkgver
  python3 setup.py build

  cd "$srcdir"/hyperlink-$pkgver-py2
  python2 setup.py build
}

check() {
  cd "$srcdir"/hyperlink-$pkgver
  python setup.py pytest

  cd "$srcdir"/hyperlink-$pkgver-py2
  python2 setup.py pytest
}

package_python3-hyperlink() {
  depends=('python3')

  cd hyperlink-$pkgver
  python3 setup.py install --root="$pkgdir" --optimize=1
  install -D -m644 LICENSE "$pkgdir"/usr/share/licenses/$pkgname/LICENSE
}

package_python2-hyperlink() {
  depends=('python2')

  cd hyperlink-$pkgver-py2
  python2 setup.py install --root="$pkgdir" --optimize=1
  install -D -m644 LICENSE "$pkgdir"/usr/share/licenses/$pkgname/LICENSE
}