# Contributions from Arch: https://www.archlinux.org/packages/extra/x86_64/p7zip/

pkgname=p7zip
pkgver=16.02
pkgrel=1
pkgdesc="A command-line port of the 7zip compression utility"
arch=('x86_64')
license=('GPL')
url="http://p7zip.sourceforge.net"
depends=('gcc-libs' 'bash')
makedepends=('yasm')
options=('!makeflags')
source=("https://downloads.sourceforge.net/project/${pkgname}/${pkgname}/${pkgver}/${pkgname}_${pkgver}_src_all.tar.bz2")
md5sums=('a0128d661cfe7cc8c121e73519c54fbf')


prepare() {
  cd "$srcdir/${pkgname}_$pkgver"
  cp makefile.linux_amd64_asm makefile.machine
}

build() {
	cd "${srcdir}/${pkgname}_${pkgver}"
	make all3 OPTFLAGS="${CXXFLAGS}"
}

package() {
	cd "${srcdir}/${pkgname}_${pkgver}"

	make install \
		DEST_DIR="${pkgdir}" \
		DEST_HOME="/usr" \
		DEST_MAN="/usr/share/man"

	# Licenses
	install -d "${pkgdir}"/usr/share/licenses/p7zip
	ln -s -t "${pkgdir}"/usr/share/licenses/p7zip \
		/usr/share/doc/p7zip/DOCS/License.txt \
		/usr/share/doc/p7zip/DOCS/unRarLicense.txt

	# Integration with stuff...
	ln -s 7zCon.sfx "${pkgdir}"/usr/lib/p7zip/7z.sfx
	chmod -R u+w "${pkgdir}/usr"
}