#
# Chakra Packages for Chakra, part of chakra-project.org
#
# maintainer abveritas[at]chakra-project[dot]org>

pkgname=pygtk
pkgver=2.22.0
pkgrel=5
pkgdesc="Python bindings for the GTK widget set"
arch=('x86_64')
license=('LGPL')
depends=('libglade' 'python2-cairo>=1.10.0' 'python2-gobject>=2.28.6')
makedepends=('python-numpy')
optdepends=('python-numpy')
options=('!libtool')
url="http://www.pygtk.org/"
source=("http://ftp.gnome.org/pub/gnome/sources/pygtk/2.22/${pkgname}-${pkgver}.tar.bz2"
        'python27.patch')
sha256sums=('4acf0ef2bde8574913c40ee4a43d9c4f43bb77b577b67147271b534501a54cc8'
            '39a30456cba055a452bb55c74ef1ff2f5f7bfaad22855b4dd569ab009b56b682')

build() {
  cd "${srcdir}/${pkgname}-${pkgver}"
  #https://bugzilla.gnome.org/show_bug.cgi?id=623965
  patch -p1 -i "${srcdir}/python27.patch"
  PYTHON=python2 ./configure --prefix=/usr
  make
}

package() {
  cd "${srcdir}/${pkgname}-${pkgver}"
  make DESTDIR="${pkgdir}" install
  sed -i -e 's#env python$#env python2#' "${pkgdir}"/usr/lib/pygtk/2.0/{,demos/}*.py
  install -m644 gtk/gtk-extrafuncs.defs "${pkgdir}/usr/share/pygtk/2.0/defs/"
}