pkgname=qt5-wayland
pkgver=5.11.2
pkgrel=1
arch=('x86_64')
url='http://qt-project.org/'
license=('GPL3' 'LGPL' 'FDL' 'custom')
pkgdesc='Provides APIs for Wayland'
depends=('qt5-declarative' 'libxcomposite')
makedepends=()
groups=('qt5')
_pkgfqn="${pkgname/5-/}-everywhere-src-${pkgver}"
source=("http://download.qt.io/official_releases/qt/${pkgver%.*}/$pkgver/submodules/${_pkgfqn}.tar.xz")
md5sums=('306f498b8df461847b64e59a895f2c1d')

prepare() {
  mkdir -p build
}

build() {
  #cd build
  
  # build bug: https://bugreports.qt.io/browse/QTBUG-54148
  #- out-of-tree build fails

  #qmake-qt5 ../${_pkgfqn}
  #qmake-qt5 ../${_pkgfqn}/src/plugins
  
  cd ${_pkgfqn}
  qmake-qt5 .
  make
}

package() {
  #cd build
  cd ${_pkgfqn}
  make INSTALL_ROOT="$pkgdir" install

  # Drop QMAKE_PRL_BUILD_DIR because reference the build dir
  find "${pkgdir}/usr/lib" -type f -name '*.prl' \
    -exec sed -i -e '/^QMAKE_PRL_BUILD_DIR/d' {} \;

  install -d "$pkgdir"/usr/share/licenses
  ln -s /usr/share/licenses/qt5-base "$pkgdir"/usr/share/licenses/${pkgname}
}