pkgbase=qt-gstreamer
pkgname=('qt4-gstreamer' 'qt5-gstreamer')
pkgver=1.2.0
pkgrel=3
arch=('x86_64')
url="http://gstreamer.freedesktop.org/modules/qt-gstreamer.html"
license=('LGPL2.1')
makedepends=('cmake' 'boost' 'mesa' 'doxygen' 'gst-plugins-good' 'qt' 'qt5-declarative')
source=("http://gstreamer.freedesktop.org/src/${pkgbase}/${pkgbase}-${pkgver}.tar.xz")
md5sums=('fd794045a828c184acc1794b08a463fd')

prepare() {
  mkdir -p build{4,5}
}

build() {
  cd build4
  cmake ../${pkgbase}-${pkgver} \
    -DCMAKE_INSTALL_PREFIX=/usr \
    -DCMAKE_BUILD_TYPE=Release \
    -DCMAKE_INSTALL_LIBDIR=lib \
    -DQTGSTREAMER_EXAMPLES=OFF \
    -DQT_VERSION=4
  make

  cd ../build5
  cmake ../${pkgbase}-${pkgver} \
    -DCMAKE_INSTALL_PREFIX=/usr \
    -DCMAKE_BUILD_TYPE=Release \
    -DCMAKE_INSTALL_LIBDIR=lib \
    -DQTGSTREAMER_EXAMPLES=OFF \
    -DQT_VERSION=5
  make
}

package_qt4-gstreamer() {
  pkgdesc="Qt4 bindings for GStreamer"
  depends=('qt' 'gst-plugins-good')
  conflicts=('qt-gstreamer')
  provides=('qt-gstreamer')
  replaces=('qt-gstreamer')

  cd build4
  make DESTDIR="${pkgdir}" install
}

package_qt5-gstreamer() {
  pkgdesc="Qt5 bindings for GStreamer"
  depends=('qt5-declarative' 'gst-plugins-good')

  cd build5
  make DESTDIR="${pkgdir}" install
}