#
# Chakra Packages for Chakra, part of chakra-project.org
#
# maintainer abveritas<manutortosa[at]chakra-project[dot]org>

pkgname=pacman
pkgver=4.0.2
pkgrel=7
pkgdesc="A library-based package manager with dependency support"
arch=('x86_64')
url="http://www.archlinux.org/pacman/"
license=('GPL')
groups=('base')
depends=('bash' 'glibc' 'libarchive>=3.0.2' 'curl>=7.19.4'
         'gpgme' 'pacman-mirrorlist')
makedepends=('asciidoc')
optdepends=('fakeroot: for makepkg usage as normal user')
backup=(etc/pacman.conf etc/makepkg.conf)
install=pacman.install
options=(!libtool)
source=(ftp://ftp.archlinux.org/other/pacman/$pkgname-$pkgver.tar.gz
        pacman.conf.x86_64
        pacman.conf
        makepkg.conf
        add_categories.patch
        https://gitorious.org/chakra/pacman-info/blobs/raw/master/pacman)
md5sums=('289ba4a19a16393096e065cec1cb9b0a'
         '7cc09e46386579933ef50cea30b8389a'
         '6c79bb013b5b6a14126ebcdaef12fdcd'
         '5beebe36bfc1e1f677d5ae12fcff8083'
         'a5d5c520ed75311d1875e0835563af33'
         '69ffe35d391118d30cf255cc2702ad1d')

build() {
  cd $srcdir/$pkgname-$pkgver
  
  # add categories array support
  patch -Np1 -i ../add_categories.patch

  ./configure --prefix=/usr --sysconfdir=/etc \
    --localstatedir=/var --enable-doc
  make
}

check() {
  make -C "$pkgname-$pkgver" check
}

package() {
  cd $srcdir/$pkgname-$pkgver
  make DESTDIR=$pkgdir install

  mkdir -p $pkgdir/etc
  install -m644 $srcdir/pacman.conf.x86_64 $pkgdir/etc/pacman.conf
  mycarch="x86_64"
  mychost="x86_64-unknown-linux-gnu"
  myflags="-march=x86-64 "

  install -m644 $srcdir/makepkg.conf $pkgdir/etc/
  # set things correctly in the default conf file
  sed -i $pkgdir/etc/makepkg.conf \
    -e "s|@CARCH[@]|$mycarch|g" \
    -e "s|@CHOST[@]|$mychost|g" \
    -e "s|@CARCHFLAGS[@]|$myflags|g"

  # install completion files
  install -Dm644 contrib/bash_completion "$pkgdir/usr/share/bash-completion/completions/pacman"
  for f in makepkg pacman-key; do
    ln -s pacman "$pkgdir/usr/share/bash-completion/completions/$f"
  done
  install -Dm644 contrib/zsh_completion $pkgdir/usr/share/zsh/site-functions/_pacman

  mv $pkgdir/usr/bin/pacman $pkgdir/usr/bin/pacmanbin
  install -Dm775 $srcdir/pacman $pkgdir/usr/bin/pacman
}