# Maintainer: Neophytos Kolokotronis <tetris4 AT gmail DOT com>

pkgbase=rxvt-unicode
pkgname=('rxvt-unicode' 'rxvt-unicode-terminfo')
pkgver=9.21
pkgrel=2
pkgdesc="An unicode enabled rxvt-clone terminal emulator (urxvt)."
arch=('x86_64')
url="http://software.schmorp.de/pkg/rxvt-unicode.html"
license=("GPL")
makedepends=('libxft' 'perl' 'startup-notification')
source=("http://dist.schmorp.de/rxvt-unicode/${pkgname}-${pkgver}.tar.bz2"
"urxvt.desktop"
"urxvtc.desktop"
"urxvt-tabbed.desktop")
md5sums=('a9a06c608258c5fd247c3725d8f44582'
         '4a041e3baa87991c415468e12bc6bcc9'
         'fac55f0a8404c86dad3e702146762332'
         '8a5599197568c63720e282b9722a7990')

build() {
  cd "${srcdir}/${pkgname}-${pkgver}"

  ./configure \
    --prefix=/usr \
    --with-terminfo=/usr/share/terminfo \
    --enable-256-color \
    --enable-combining \
    --enable-fading \
    --enable-font-styles \
    --enable-iso14755 \
    --enable-keepscrolling \
    --enable-lastlog \
    --enable-mousewheel \
    --enable-next-scroll \
    --enable-perl \
    --enable-pointer-blank \
    --enable-rxvt-scroll \
    --enable-selectionscrolling \
    --enable-slipwheeling \
    --disable-smart-resize \
    --enable-startup-notification \
    --enable-transparency \
    --enable-unicode3 \
    --enable-utmp \
    --enable-wtmp \
    --enable-xft \
    --enable-xim \
    --enable-xterm-scroll \
    --enable-pixbuf \
    --disable-frills
  make
}

package_rxvt-unicode() {
  pkgdesc='A unicode enabled rxvt-clone terminal emulator (urxvt)'
  depends=('rxvt-unicode-terminfo' 'libxft' 'perl' 'startup-notification')
  optdepends=('gtk2-perl: to use the urxvt-tabbed')

  # install freedesktop menu
  for _f in urxvt urxvtc urxvt-tabbed; do
    install -Dm644 $_f.desktop "$pkgdir/usr/share/applications/$_f.desktop"
  done

  cd "${pkgname}-${pkgver}"
  export TERMINFO="$srcdir/terminfo"
  install -d "$TERMINFO"
  make DESTDIR="${pkgdir}" install

  # install the tabbing wrapper ( requires gtk2-perl! )
  sed -i 's/\"rxvt\"/"urxvt"/' doc/rxvt-tabbed
  install -Dm 755 doc/rxvt-tabbed "${pkgdir}/usr/bin/urxvt-tabbed"
}

package_rxvt-unicode-terminfo() {
  pkgdesc='Terminfo files for urxvt'
  conflict=('rxvt-unicode<=9.18-6')

  install -dm 755 "$pkgdir/usr/share/"
  mv terminfo "$pkgdir/usr/share/"
}

# vim:set ts=2 sw=2 et: