#
# Core Packages for Chakra, part of chakra-project.org
#
# maintainer (x86_64): AlmAck <almack[at]chakraos[dot]org>

pkgname=pcre
pkgver=8.37
pkgrel=2
pkgdesc="A library that implements Perl 5-style regular expressions"
arch=('x86_64')
url="http://www.pcre.org/"
license=('BSD')
depends=('gcc-libs' 'readline' 'zlib' 'bzip2')
validpgpkeys=('45F68D54BBE23FB3039B46E59766E084FB0F43D8') # Philip Hazel
source=("ftp://ftp.csx.cam.ac.uk/pub/software/programming/pcre/$pkgname-$pkgver.tar.bz2"{,.sig}
        '01-seven-security-patches.patch')
md5sums=('ed91be292cb01d21bc7e526816c26981'
         'SKIP'
         '45df6737e61738cc8bb061e0b9c0fbb2')

prepare() {
  patch -p1 -d $pkgname-$pkgver < 01-seven-security-patches.patch
}

build() {
  cd ${pkgname}-${pkgver}
  ./configure --prefix=/usr \
    --enable-unicode-properties \
    --enable-utf8 \
    --enable-pcre16 \
    --enable-pcre32 \
    --enable-jit \
    --enable-pcregrep-libz \
    --enable-pcregrep-libbz2 \
    --enable-pcretest-libreadline
  make
}

check() {
  cd ${pkgname}-${pkgver}
  make -j1 check
}

package() {
  cd ${pkgname}-${pkgver}
  make DESTDIR="${pkgdir}" install

  install -Dm644 LICENCE "${pkgdir}"/usr/share/licenses/${pkgname}/LICENSE
}