#
# Chakra Packages for Chakra, part of chakra-project.org
#
# maintainer (i686): Phil Miller <philm[at]chakra-project[dog]org>
# maintainer (x86_64): Manuel Tortosa <manutortosa[at]chakra-project[dot]org>

# include global config
source ../_buildscripts/${current_repo}-${_arch}-cfg.conf

pkgname=ffmpeg
pkgver=0.8.3
pkgrel=1
pkgdesc="Complete and free Internet live audio and video broadcasting solution for Linux/Unix."
arch=('i686' 'x86_64')
url="http://ffmpeg.org/"
license=('GPL3')
depends=('bzip2' 'lame' 'sdl' 'libvorbis' 'xvidcore' 'zlib' 'x264' 'libtheora' 'opencore-amr' 'alsa-lib' 'libvdpau' 'libxfixes' 'schroedinger' 'libva' 'openjpeg' 'libvpx' 'rtmpdump')
makedepends=('yasm')
options=('force')
source=('http://www.ffmpeg.org/releases/ffmpeg-0.8.3.tar.bz2')
md5sums=('7e9b8c8a6952de0c477027e48249f3ed')

build() {

  cd $srcdir/$pkgbase-$pkgver

  ./configure \
    --prefix=/usr \
    --enable-gpl \
    --enable-version3 \
    --enable-libmp3lame \
    --enable-libvorbis \
    --enable-libxvid \
    --enable-libx264 \
    --enable-libtheora \
    --enable-postproc \
    --enable-shared \
    --enable-x11grab \
    --enable-libopencore_amrnb \
    --enable-libopencore_amrwb \
    --enable-libschroedinger \
    --enable-libopenjpeg \
    --enable-runtime-cpudetect \
    --enable-libvpx \
    --enable-librtmp \
    --disable-debug

  make
  make tools/qt-faststart
  make doc/ff{mpeg,play,server}.1
}

package() {
  cd $srcdir/$pkgbase-$pkgver

  make DESTDIR="${pkgdir}" install install-man
  install -D -m755 tools/qt-faststart "${pkgdir}/usr/bin/qt-faststart"
}

# vim:set ts=2 sw=2 et: