#
# Core Packages for Chakra, part of chakra-project.org
#
# maintainer (i686): Phil Miller <philm[at]chakra-project[dog]org>
# maintainer (x86_64): Manuel Tortosa <manutortosa[at]chakra-project[dot]org>

pkgname=dbus-core
pkgver=1.4.14
pkgrel=2
pkgdesc="Freedesktop.org message bus system."
url="http://www.freedesktop.org/Software/dbus"
arch=('i686' 'x86_64')
license=('GPL' 'custom')
depends=('expat>=2.0.1' 'coreutils' 'filesystem')
makedepends=('libx11')
conflicts=('dbus<1.2.3-2')
options=(!libtool)
install="dbus.install"
source=("http://dbus.freedesktop.org/releases/dbus/dbus-${pkgver}.tar.gz"
        'dbus')
md5sums=('ae6de2562a57516cfabaf56903375ba9'
         '81eb58bbe2b2212210e592ccd1eb5c3c')

build() {
  cd "${srcdir}/dbus-${pkgver}"

  ./configure --prefix=/usr \
              --sysconfdir=/etc --localstatedir=/var \
              --libexecdir=/usr/lib/dbus-1.0 \
              --with-dbus-user=81 \
              --with-system-pid-file=/var/run/dbus.pid \
              --enable-inotify \
              --disable-dnotify \
              --disable-verbose-mode \
              --disable-static \
              --disable-tests \
              --disable-asserts \
              --with-systemdsystemunitdir=/lib/systemd/system

  make
}

package(){
  cd "${srcdir}/dbus-${pkgver}"
  make DESTDIR="${pkgdir}" install

  rm -f "${pkgdir}/usr/bin/dbus-launch"
  rm -f "${pkgdir}/usr/share/man/man1/dbus-launch.1"

  chown 81:81 "${pkgdir}/var/run/dbus"

  install -m755 -d "${pkgdir}/etc/rc.d"
  install -m755 "${srcdir}/dbus" "${pkgdir}/etc/rc.d/"

  # Fix configuration file
  sed -i -e 's|<user>81</user>|<user>dbus</user>|' "${pkgdir}/etc/dbus-1/system.conf"

  # Install .keep files so pacman doesn't delete empty dirs
  touch "${pkgdir}/usr/share/dbus-1/services/.keep"
  touch "${pkgdir}/usr/share/dbus-1/system-services/.keep"
  touch "${pkgdir}/etc/dbus-1/session.d/.keep"
  touch "${pkgdir}/etc/dbus-1/system.d/.keep"

  install -d -m755 "${pkgdir}/usr/share/licenses/dbus-core"
  install -m644 COPYING "${pkgdir}/usr/share/licenses/dbus-core/"
}

# vim:set ts=2 sw=2 et: