#contributions from Arch: https://projects.archlinux.org/svntogit/packages.git/tree/trunk?h=packages/isdn4k-utils

pkgname=isdn4k-utils
pkgver=3.27
pkgrel=1
pkgdesc="User space administration programs and tools for ISDN"
arch=('x86_64')
url="http://www.isdn4linux.de/"
license=('GPL')
depends=('ncurses' 'sh') 
backup=(etc/isdn/{callerid.conf,isdn.conf,rate.conf,isdnlog.isdnctrl0.options})
options=('!makeflags')
source=(isdn4k-utils::git+git://git.misdn.eu/isdn4k-utils.git#tag=v${pkgver}
        config
        va_list.patch)
md5sums=('SKIP'
         'd3be8bf50f21bff277deff5e3bc46ef9'
         '5bce7606c04bb51a4e6527a5ff56c87e')

prepare() {
  CPPFLAGS="$CPPFLAGS -O2"
  cd $srcdir/$pkgname
  patch -Np1 -i $srcdir/va_list.patch
  cp $srcdir/config ./.config
  cd capiinfo
  aclocal
  automake --add-missing
  autoreconf
  cd $srcdir/$pkgname
  cd capifax
  aclocal 
  automake --add-missing
  autoreconf
  cd $srcdir/$pkgname
  make subconfig
}

build() {
  cd $srcdir/$pkgname
  make
}

package() {
  cd $srcdir/$pkgname
  install -dm755 $pkgdir/usr/bin
  make DESTDIR=$pkgdir install
  chmod 755 $pkgdir/usr/bin/*
}