#
# Chakra Packages for Chakra, part of chakra-project.org
#
# maintainer (i686): Phil Miller <philm[at]chakra-project[dog]org>
# maintainer (x86_64): Manuel Tortosa <manutortosa[at]chakra-project[dot]org>

pkgname=wicd
pkgver=1.7.0
pkgrel=6
pkgdesc="New and alternative wireless/wired network management utility"
arch=('i686' 'x86_64')
url="http://wicd.sourceforge.net/"
license=('GPL2')
depends=('python2' 'dbus-python' 'dhcpcd' 'wpa_supplicant' 'wireless_tools'
           'net-tools' 'ethtool' 'shared-mime-info' 'python-urwid' 'pygobject')
optdepends=('python-wpactrl:	needed if you want to use the new experimental ioctrl backend'
	    'python-iwscan:	needed if you want to use the new experimental ioctrl backend'
	    'wicd-client-kde:	needed if you want to use kde ui')
conflicts=('wicd-svn')
install=wicd.install
source=(http://downloads.sourceforge.net/sourceforge/$pkgname/$pkgname-$pkgver.tar.gz
        wicd-daemon
        wicd.desktop
	wicd-scripts-execution.patch
        deepcopy+python27-fixes.patch
	net-tools.patch)
categories=('network')
options=('emptydirs')
backup=('etc/wicd/encryption/templates/active')
md5sums=('003d2e67240989db55934553437ba32a'
         'f40e5f59998d0829707a7c9976afa8f8'
         '326df163a5732d38741371baa4fce9e5'
         'f4c377a25aa077cb76955124adfcc03f'
         '4f94d05b28aa2ae1cc37b29ef069fe51'
         'f18c4adf741bf3b1a55b4a6bc772f485')

build() {
  cd $srcdir/$pkgbase-$pkgver
  patch -p0 <$srcdir/wicd-scripts-execution.patch
  patch -p1 -i $srcdir/deepcopy+python27-fixes.patch
  patch -p0 -i $srcdir/net-tools.patch

  find . -type f -exec sed -i 's@#!/usr.*python@#!/usr/bin/python2@' {} \;
  export PYTHON=python2
  python2 setup.py configure --no-install-init \
	                     --resume=/usr/share/wicd/scripts/ \
                             --suspend=/usr/share/wicd/scripts/ \
                             --verbose \
                             --python=/usr/bin/python2
  python2 setup.py install --optimize=1 --root=$pkgdir

  # Add custom rc.d script
  install -Dm755 $srcdir/wicd-daemon $pkgdir/etc/rc.d/wicd
  #install -Dm644 $srcdir/wicd.desktop $pkgdir/usr/share/applications/wicd.desktop

  cd build/lib/wicd
  for i in *.py; do
    install -Dm 755 $i $pkgdir/usr/lib/wicd/$i
  done
  
  rm -rf $pkgdir/usr/share/autostart

  #deleting the GTK stuff
  rm -rf $pkgdir/etc/xdg
  rm -f $pkgdir/usr/bin/{wicd-client,wicd-gtk}
  rm -rf $pkgdir/usr/share/{applications,icons,pixmaps}
  rm -rf $pkgdir/usr/share/wicd/gtk  
}