# Maintainer: Phil Miller <philm[at]chakra-project[dot]org>
# Committer: Simone Tobia <simone.tobia at gmail dot com>
# Translators: http://chakra-project.org/bbs/viewtopic.php?pid=29626#p29626

pkgname=appset-qt
pkgver=0.3.3
pkgrel=0.2
pkgdesc="An advanced and feature rich Package Manager Frontend"
arch=('i686' 'x86_64')
url="http://appset.sourceforge.net/"
license=('GPL2')
depends=('qt>=4.7')
optdepends=('kdebase-konqueror: For displaying Webpages in fullscreen')
install=${pkgname}.install
source=(http://sourceforge.net/projects/appset/files/appset-qt/0.3/$pkgver/$pkgname-$pkgver-sources.tar.gz
        http://chakra-project.org/sources/$pkgname/appset-qt-oxygen-icons.tar.xz
        http://chakra-project.org/sources/$pkgname/$pkgname-0.3.3-chakra.patch
        #http://chakra-project.org/sources/$pkgname/add-spanish.patch
        http://chakra-project.org/sources/$pkgname/appset-qt_de-0.3.3.tar.gz
        http://chakra-project.org/sources/$pkgname/appset-qt_el-0.3.3.tar.gz
        http://chakra-project.org/sources/$pkgname/appset-qt_es-0.3.3.tar.gz
        http://chakra-project.org/sources/$pkgname/appset-qt_fr-0.3.3.tar.gz
        http://chakra-project.org/sources/$pkgname/appset-qt_nl-0.3.3.tar.gz)
md5sums=(a5710cf544751cd0bbaff9ecc5e4d4cd
         87f5f278e3fe67ed2cd6165c2835d81b
         6eac74dda44791729468de2e6c80d9a6 
         #0bebc346942eec90bb6a99f2f58e477f
         2463dc389ca4c8fe20871b9737cec890
         b78bc3c07aeb6af2bc6852282820ca1a
         576d650fe07e421b6971182ecac5c8a9
         daae1071c45c538a9e3db2af56615d82
         7f0e642b9430bcbacfa43803dfd6ebfb)

build() {
  cd $srcdir/$pkgname-$pkgver-sources
  # copy oxygen icons
  cp -v ../*png Qt/AppSet-Qt

  # patch it for Chakra GNU/Linux
  patch -Np1 -i ${startdir}/src/$pkgname-0.3.3-chakra.patch

  # add chakra translations (check upstream)
  #patch -Np1 -i ${startdir}/src/add-spanish.patch
  cp -v ../appsettray-qt*.ts Qt/AppSetTray-Qt
  cp -v ../appset-qt*.ts Qt/AppSet-Qt

  # check for updated strings
  cd Qt/AppSet-Qt
  lupdate *.cpp *.ui *.h -ts appset*-qt_*.ts
  cd ../AppSetTray-Qt
  lupdate *.cpp *.h -ts appsettay*-qt_*.ts
  cd ../..

  qmake PREFIX=/usr -Wnone

  #localization
  lrelease Qt/AppSet-Qt/*.ts
  lrelease Qt/AppSetTray-Qt/*.ts

  make || return 1
}

package() {
    cd $srcdir/$pkgname-$pkgver-sources

    make INSTALL_ROOT="$pkgdir/" install

    #helper daemon
    install -m 755 -d "$pkgdir/etc/rc.d" || return 1
    install -m 755 "$srcdir/$pkgname-$pkgver-sources/AppSetHelper/appset-helper.sh" "$pkgdir/etc/rc.d/appset-helper"
}