# maintainer (i686): Phil Miller <philm[at]chakra-project[dog]org>
# maintainer (x86_64): Manuel Tortosa <manutortosa[at]chakra-project[dot]org>

pkgname=libqzeitgeist
pkgver=0.8.0
pkgrel=3
pkgdesc="A Qt interface to the Zeitgeist event tracking system"
url="https://projects.kde.org/projects/kdesupport/libqzeitgeist"
arch=('i686' 'x86_64')
license=('GPL')
depends=('qt')
makedepends=('cmake' 'automoc4' 'python2' 'zeitgeist')
source=("http://download.kde.org/stable/${pkgname}/${pkgver}/src/${pkgname}-${pkgver}.tar.bz2"
        'set-declarative-installation-dir.patch')
md5sums=('97bdea6a1865db7d5f29c93e3a492f24'
         'd111c473314a9fe0add4888c7469b5ca')

prepare() {
  cd "${srcdir}/${pkgname}-${pkgver}"
  patch -p1 -i "${srcdir}"/set-declarative-installation-dir.patch
}

build() {
  cd "${srcdir}/${pkgname}-${pkgver}"
  [[ -d build ]] && rm -rf build ; mkdir build
  cd build
  cmake -DCMAKE_BUILD_TYPE=Release \
	-DCMAKE_INSTALL_PREFIX=/usr \
        -DDECLARATIVE_IMPORT_PREFIX=/usr/lib/qt/imports/ ..
  make
}

package() {
  cd "${srcdir}/${pkgname}-${pkgver}/build"
  make DESTDIR="${pkgdir}" install
}