# maintainer abveritas[at]chakra-project[dot]org>

pkgbase=vigra
pkgname=('vigra' 'vigra-doc')
pkgver=1.10.0
pkgrel=3
pkgdesc="Computer vision library"
arch=('x86_64')
url="http://hci.iwr.uni-heidelberg.de/vigra/"
license=('custom:MIT')
makedepends=( # runtime deps
             'libpng' 'libtiff' 'hdf5' 'fftw' 'openexr'
              # buildtime deps
             'cmake' 'python2-nose' 'doxygen' 'python2-sphinx' 'boost' 'python2-numpy' 'python3-sphinx')
source=("https://github.com/ukoethe/vigra/releases/download/Version-${pkgver//./-}/${pkgname}-${pkgver}-src-with-docu.tar.gz")
md5sums=('85e2968e4ee5f9541b5dd8b3fb9cc433')

build() {
  cd "${srcdir}"/${pkgname}-${pkgver}
  
  cmake -DCMAKE_INSTALL_PREFIX=/usr \
      -DPYTHON_EXECUTABLE=/usr/bin/python2 \
      -DWITH_VIGRANUMPY=1 \
      -DWITH_OPENEXR=1 \
      -DDOCINSTALL=share/doc 
  make
}

#check() {
#  cd "${srcdir}"/${pkgname}-${pkgver}
#  make -k check
#}
# Currently failed due to limitation of buildsystem

package_vigra() {
  depends=('libpng' 'libtiff' 'hdf5' 'fftw' 'openexr')
  optdepends=('python2: for python bindings'
              'boost-libs: for python bindings')

  cd "${srcdir}"/${pkgname}-${pkgver}
  make DESTDIR="${pkgdir}" install
  # license
  install -D -m644 LICENSE.txt "${pkgdir}"/usr/share/licenses/${pkgname}/LICENSE

  # remove doc
  rm -rf "${pkgdir}"/usr/share/doc

  #fix shebang for python2
  sed -i 's|python$|python2|' "$pkgdir"/usr/bin/vigra-config
}

package_vigra-doc() {
  pkgdesc+=" - documentation and examples"

  cd "${srcdir}"/${pkgbase}-${pkgver}
  make DESTDIR="${pkgdir}" install
  # cleanup
  rm -rf "${pkgdir}"/usr/{bin,include,lib}

  # license
  install -D -m644 LICENSE.txt "${pkgdir}"/usr/share/licenses/${pkgname}/LICENSE
}