# arch contributor: https://projects.archlinux.org/svntogit/packages.git/plain/trunk/PKGBUILD?h=packages/libkate

pkgname=libkate
pkgver=0.4.1
pkgrel=1
pkgdesc="A karaoke and text codec for embedding in ogg"
url="http://libkate.googlecode.com/"
license=('BSD')
arch=('i686' 'x86_64')
depends=('libpng' 'libogg' 'python2')
makedepends=('pkg-config')
optdepends=('wxpython: for KateDJ'
            'liboggz: for KateDJ')
source=("http://libkate.googlecode.com/files/${pkgname}-${pkgver}.tar.gz")
md5sums=('1dfdbdeb2fa5d07063cf5b8261111fca')

build() {
  cd "${srcdir}/${pkgname}-${pkgver}"

  export PYTHON="/usr/bin/python2"
  sed "1s/python$/python2/" -i tools/KateDJ/KateDJ

  ./configure --prefix=/usr \
              --disable-static \
              --disable-doc
  make
}

package() {
  cd "${srcdir}/${pkgname}-${pkgver}"
  make DESTDIR="${pkgdir}" install
  install -Dm644 COPYING "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE"

  python2 -m compileall "${pkgdir}/usr/lib/python2.7/site-packages/kdj/"
}