# Part of the X.org group
# Maintainer: Neophytos Kolokotronis <tetris4@gmail.com>

pkgname=libxext
pkgver=1.3.2
pkgrel=2
pkgdesc="X11 miscellaneous extensions library"
arch=(x86_64)
url=('http://xorg.freedesktop.org/')
license=('custom')
depends=('libx11' 'xextproto')
makedepends=('pkg-config')
options=('!libtool')
source=("${url}/releases/individual/lib/libXext-${pkgver}.tar.bz2"
        'Xge-remove-warning-messages-about-missing-Xge-extension-event-translations.patch')
sha1sums=('49b6f026b0555d020014dbc24b49afc2986a30e0'
          '09960cacd166e61a312c46ebfec9f6d55b66cc48')

prepare() {
  cd "${srcdir}/libXext-${pkgver}"
  patch -Np1 -i $srcdir/Xge-remove-warning-messages-about-missing-Xge-extension-event-translations.patch
}

build() {
  cd "${srcdir}/libXext-${pkgver}"
  ./configure --prefix=/usr --sysconfdir=/etc --disable-static
  make
}

package() {
  cd "${srcdir}/libXext-${pkgver}"
  make DESTDIR="${pkgdir}" install

  install -m755 -d "${pkgdir}/usr/share/licenses/${pkgname}"
  install -m644 COPYING "${pkgdir}/usr/share/licenses/${pkgname}/"
}