#
# Chakra Packages for Chakra, part of chakra-project.org
#
# maintainer (i686): Phil Miller <philm[at]chakra-project[dog]org>
# maintainer (x86_64): Manuel Tortosa <manutortosa[at]chakra-project[dot]org>

# include global config
source ../_buildscripts/${current_repo}-${_arch}-cfg.conf

pkgname=lightspark
pkgver=0.4.3
pkgrel=1
pkgdesc='An alternative Flash Player for Linux - Flash for real. Now.'
arch=('i686' 'x86_64')
url='http://lightspark.sourceforge.net'
license=('LGPL3')
conflicts=('lightspark-git')
depends=('mesa' 'ftgl' 'sdl' 'gtk2' 'curl' 'zlib' 'ffmpeg' 'glew>=1.5.4' 'pcre' 'pulseaudio' 'libffi') 
makedepends=('cmake' 'nasm' 'xulrunner' 'llvm' 'glproto')
source=("http://launchpad.net/${pkgname}/trunk/${pkgname}-${pkgver:0:5}/+download/${pkgname}-${pkgver}.tar.gz")
md5sums=('5871dc4d685b54f46f8e5363725f03ef')

build() {
  [ -d build ] && rm -rf build
  mkdir build
  cd build

  cmake \
    -DCMAKE_INSTALL_PREFIX=/usr \
    -DCOMPILE_PLUGIN=1 \
    -DCMAKE_BUILD_TYPE=Release \
    ../${pkgname}-${pkgver}

  make
} 

package() {
  cd build

  make DESTDIR=${pkgdir} install
}