# $Id: PKGBUILD 71240 2010-03-05 16:09:12Z jgc $
# Maintainer: Jan de Groot <jgc@archlinux.org>

pkgbase=poppler
pkgname=('poppler' 'poppler-glib' 'poppler-qt')
pkgver=0.12.4
pkgrel=1
arch=(i686 x86_64)
license=('GPL')
makedepends=('libjpeg>=8' 'gcc-libs>=4.4.3' 'cairo>=1.8.10' 'libxml2>=2.7.6' 'fontconfig>=2.8.0' 'openjpeg>=1.3-3' 'gtk2>=2.18.7' 'qt>=4.6.2' 'pkgconfig' 'lcms>=1.18')
options=('!libtool')
url="http://poppler.freedesktop.org/"
source=(http://poppler.freedesktop.org/${pkgname}-${pkgver}.tar.gz)
md5sums=('4155346f9369b192569ce9184ff73e43')

build() {
  cd "${srcdir}/${pkgname}-${pkgver}"
  ./configure --prefix=/usr --sysconfdir=/etc \
      --localstatedir=/var --disable-static \
      --enable-cairo-output \
      --enable-xpdf-headers \
      --enable-libjpeg --enable-zlib \
      --enable-poppler-qt4 \
      --enable-poppler-glib || return 1
  make || return 1
}

package_poppler() {
  pkgdesc="PDF rendering library based on xpdf 3.0"
  depends=('libjpeg>=8' 'gcc-libs>=4.4.3' 'cairo>=1.8.10' 'libxml2>=2.7.6' 'fontconfig>=2.8.0' 'openjpeg>=1.3-3' 'lcms>=1.18')
  optdepends=('poppler-data')
  conflicts=("poppler-qt3<${pkgver}")

  cd "${srcdir}/${pkgbase}-${pkgver}"
  make DESTDIR="${pkgdir}" install || return 1

  rm -rf "${pkgdir}"/usr/include/poppler/{glib,qt4}
  rm -f "${pkgdir}"/usr/lib/libpoppler-{glib,qt4}.so*
  rm -f "${pkgdir}"/usr/lib/pkgconfig/poppler-{glib,qt4}.pc
  rm -rf "${pkgdir}/usr/share/gtk-doc"
}


package_poppler-glib() {
  pkgdesc="Poppler glib bindings"
  depends=("poppler=${pkgver}" 'gtk2>=2.18.7')

  cd "${srcdir}/${pkgbase}-${pkgver}/poppler"
  make DESTDIR="${pkgdir}" install-libLTLIBRARIES || return 1
  cd "${srcdir}/${pkgbase}-${pkgver}/glib"
  make DESTDIR="${pkgdir}" install || return 1
  install -m755 -d "${pkgdir}/usr/lib/pkgconfig"
  install -m644 ../poppler-glib.pc "${pkgdir}/usr/lib/pkgconfig/" || return 1
  rm -f "${pkgdir}"/usr/lib/libpoppler.*
}

package_poppler-qt() {
  pkgdesc="Poppler Qt bindings"
  depends=("poppler=${pkgver}" 'qt>=4.6.2')

  cd "${srcdir}/${pkgbase}-${pkgver}/poppler"
  make DESTDIR="${pkgdir}" install-libLTLIBRARIES || return 1
  cd "${srcdir}/${pkgbase}-${pkgver}/qt4"
  make DESTDIR="${pkgdir}" install || return 1
  install -m755 -d "${pkgdir}/usr/lib/pkgconfig"
  install -m644 ../poppler-qt4.pc "${pkgdir}/usr/lib/pkgconfig/" || return 1
  rm -f "${pkgdir}"/usr/lib/libpoppler.*
}