# $Id: PKGBUILD 71032 2010-03-03 10:37:48Z dgriffiths $
# Maintainer: Jan de Groot <jgc@archlinux.org>

pkgname=xdg-utils
pkgver=1.0.2.20100303
pkgrel=1
pkgdesc='Command line tools that assist applications with a variety of desktop integration tasks.'
arch=('any')
url='http://portland.freedesktop.org/'
depends=('sh')
makedepends=('docbook-xsl' 'lynx' 'xmlto')
optdepends=('xorg-utils: needed if using Xfce')
license=('custom')
source=("ftp://ftp.archlinux.org/other/${pkgname}/${pkgname}-${pkgver}.tar.xz")
md5sums=('b4a9ea7a85559fdebc06c2f703b5116f')

build() {
	cd ${srcdir}/${pkgname}-${pkgver}
	./configure --prefix=/usr --mandir=/usr/share/man || return 1
	cd scripts
	make scripts html man || return 1
	cd ..
	make || return 1
}

package() {
	cd ${srcdir}/${pkgname}-${pkgver}
	make DESTDIR=${pkgdir} install || return 1
	install -D -m644 LICENSE ${pkgdir}/usr/share/licenses/${pkgname}/LICENSE
}

_source() {
	local _current=$(pwd)
	local _tmp=$(mktemp -d)
	cd $_tmp

	cvs -d:pserver:anoncvs@anoncvs.freedesktop.org:/cvs/portland co -d ${pkgname}-${pkgver} portland/xdg-utils
	find ${pkgname}-${pkgver} -name 'CVS' -type d -exec rm -rf {} \;
	bsdtar cvzf ${pkgname}-${pkgver}.tar.gz ${pkgname}-${pkgver}
	mv ${pkgname}-${pkgver}.tar.gz $_current
	cd $_current
	rm -rf $_tmp
}