#
# Software packages for Chakra, part of www.chakra-project.org
#
# Maintainer:   H W Tovetjärn (totte) <totte@tott.es>
# Contributors: R Biegelmeyer (RenanBS) <renan.biegel@gmail.com>
#               Evangelos Foutras <evangelos@foutrelis.com>
#               T Preetz <timm@preetz.us>

pkgbase=python-pygments
pkgname=('python3-pygments' 'python2-pygments')
pkgver=1.6
pkgrel=4
pkgdesc="Python syntax highlighter"
arch=('any')
url="http://pygments.org/"
license=('BSD')
makedepends=('python3-setuptools' 'python2-setuptools')
options=(!emptydirs)
source=(http://pypi.python.org/packages/source/P/Pygments/Pygments-$pkgver.tar.gz
        make-pygments.lexers.guess_lexer_for_filename-py3-compatible.patch)
md5sums=('a18feedf6ffd0b0cc8c8b0fbdb2027b1'
         '417f20255f7410065e73269b52497f1f')

prepare() {
  cd "$srcdir/Pygments-$pkgver"

  patch -Np1 -i "$srcdir/make-pygments.lexers.guess_lexer_for_filename-py3-compatible.patch"
}

build() {
  cd "$srcdir"

  rm -rf python{2,3}-build
  for builddir in python{2,3}-build; do
    cp -r Pygments-$pkgver $builddir
    pushd $builddir
    ${builddir%-build} setup.py build
    popd
  done
}

package_python3-pygments() {
  depends=('python3-setuptools')

  cd "$srcdir/python3-build"

  python3 setup.py install --root="$pkgdir" -O1

  # pygmentize has been moved to the python2-pygments package
  rm "$pkgdir/usr/bin/pygmentize"

  install -Dm644 LICENSE "$pkgdir/usr/share/licenses/$pkgname/LICENSE"
}

package_python2-pygments() {
  depends=('python2-setuptools')
  conflicts=('pygments')
  replaces=('pygments')
  provides=('python-pygments' 'pygments')

  cd "$srcdir/python2-build"

  python2 setup.py install --root="$pkgdir" -O1

  install -Dm644 external/pygments.bashcomp \
    "$pkgdir/usr/share/bash-completion/completions/pygmentize"

  install -Dm644 LICENSE "$pkgdir/usr/share/licenses/$pkgname/LICENSE"
}