#
# Chakra Packages for Chakra, part of chakra-project.org
#
# maintainer (i686): Phil Miller <philm[at]chakra-project[dog]org>
# maintainer (x86_64): Manuel Tortosa <manutortosa[at]chakra-project[dot]org>

# include global config
source ../_buildscripts/${current_repo}-${_arch}-cfg.conf

pkgname=xorg-apps
pkgver=7.6
pkgrel=1
pkgdesc="Various X.Org applications"
arch=(i686 x86_64)
url="http://xorg.freedesktop.org/"
license=('custom')
depends=(libxcursor libxkbfile 'libpng>=1.4.0' libxft libfontenc libxaw)
makedepends=(pkgconfig xbitmaps)
source=(${url}/releases/individual/app/oclock-1.0.2.tar.bz2
        ${url}/releases/individual/app/luit-1.1.0.tar.bz2
        ${url}/releases/individual/app/xclock-1.0.5.tar.bz2
        ${url}/releases/individual/app/xpr-1.0.3.tar.bz2
        ${url}/releases/individual/app/xwd-1.0.4.tar.bz2
        ${url}/releases/individual/app/xwud-1.0.3.tar.bz2
        ${url}/releases/individual/app/x11perf-1.5.3.tar.bz2
        ${url}/releases/individual/app/xbiff-1.0.3.tar.bz2
        ${url}/releases/individual/app/xclipboard-1.1.1.tar.bz2
        ${url}/releases/individual/app/xconsole-1.0.4.tar.bz2
        ${url}/releases/individual/app/xcursorgen-1.0.4.tar.bz2
        ${url}/releases/individual/app/xeyes-1.1.1.tar.bz2
        ${url}/releases/individual/app/xkill-1.0.3.tar.bz2
        ${url}/releases/individual/app/xload-1.1.0.tar.bz2
        ${url}/releases/individual/app/xlogo-1.0.3.tar.bz2
        ${url}/releases/individual/app/xmag-1.0.4.tar.bz2
        ${url}/releases/individual/app/xmessage-1.0.3.tar.bz2
        ${url}/releases/individual/app/xcalc-1.0.4.tar.bz2
        ${url}/releases/individual/app/xman-1.1.1.tar.bz2
        ${url}/releases/individual/app/xedit-1.2.0.tar.bz2
        LICENSE)
md5sums=('353d939113901ea3cdcf1c0369b522e4'
         'cb9377b09e562e4084cc614a44df2641'
         'eaf124bbc9d13e1a12a29faaa2ed3612'
         '1c2c540d240def3ea65ff2030f059f8a'
         'ecd9167fbfdfc3cfef7e0bb089edd25b'
         'a37020053e8ee32c6fd1145242d53ee3'
         'c3ac3667a6f5c3cead9847fbf4b5f36e'
         'f38a0c63c2a7ed6fb9d6f8884785b5c9'
         'b9102fe787eda2a1c9578079d8f55eed'
         '8665c037032e5f6a3acd4b341749aa17'
         '731c39ea88217c12ddd37f8627d97f3f'
         'a3035dcecdbdb89e864177c080924981'
         'e7f0d57b6ba49c384e9cf8c9ff3243c1'
         '5f6e8c54da51ad0e751abf54980b0ef1'
         '8149f95f5a0f04f404549363557eef41'
         '2a76128511214bde973258baef537be3'
         '76ac52710234ebb9d0e2762bb5d11ea1'
         '261ccaa767420ece55bceeff9463e7e6'
         '56a00ccb38996c3518f14bb87c03a03e'
         'f55e84713542a36887e966fc0648dd7b'
         '1a3977bcff6dc0fc1086e0650fcea31a')

build() {
  cd "${srcdir}"
  for i in *; do
    if [ -d "${i}" ]; then
      pushd "${i}"
      case "${i}" in 
        x11perf*)
          sed -e 's|^LIBPATH = $(libdir)|LIBPATH = $(datadir)|' \
	          -i Makefile.* || return 1
	      ;;
	      xedit*)
	        sed -e 's|^XEDITDIR = ${libdir}|XEDITDIR = ${datadir}|' \
	          -i Makefile.* || return 1
	      ;;
        xcursorgen*)
          sed -e 's/libpng12/libpng14/g' -i configure
        ;;
      esac
      ./configure --prefix=/usr --disable-xprint --mandir=/usr/share/man \
        --with-localealiasfile=/usr/share/X11/locale/locale.alias
      make || return 1
      make DESTDIR="${pkgdir}" install || return 1
      popd
    fi
  done
  install -D -m644 LICENSE "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE"
}