# Contributor: Andrea Scarpino <andrea@archlinux.org>
# Contributor: Pierre Schmitz <pierre@archlinux.de>

source ../frameworks.conf

pkgname=kf5-akonadi-git
pkgver=v1.11.0.r81.g1894a32
pkgrel=1
arch=('i686' 'x86_64')
url='http://community.kde.org/KDE_PIM/Akonadi'
pkgdesc="PIM layer, which provides an asynchronous API to access all kind of PIM data"
license=('LGPL')
depends=('qt5-base' 'shared-mime-info' 'boost-libs' 'mariadb')
makedepends=('cmake' 'boost' 'postgresql' 'git')
optdepends=('postgresql: PostgreSQL backend')
options=("debug")
install=akonadi.install
conflicts=('kf5-akonadi')
provides=('kf5-akonadi')
source=("git://anongit.kde.org/akonadi.git")
md5sums=('SKIP')

pkgver() {
  cd akonadi
  git describe --long | sed -E 's/([^-]*-g)/r\1/;s/-/./g'
}

prepare() {
  mkdir build
}

build() {
  cd build
  cmake ../akonadi \
    -DCMAKE_BUILD_TYPE=${KFBuildType}\
    -DCMAKE_INSTALL_PREFIX=${KFInstallPrefix} \
    -DQT5_BUILD=ON \
    -DWITH_SOPRANO=OFF
  make
}

check() {
  cd build
  msg "why are those failing?"
  make test || return 0
}

package() {
  cd build
  make DESTDIR="${pkgdir}" install
}