pkgbase="foomatic"
pkgname=('foomatic-db' 'foomatic-db-engine' 'foomatic-db-nonfree')
arch=('x86_64')
_snapdate=20161210
_relver=4.0
pkgver=${_relver}_${_snapdate}
pkgrel=2
makedepends=('cups' 'perl' 'libxml2' 'enscript' 'perl' 'net-snmp' 'bash')
source=("http://www.openprinting.org/download/foomatic/${pkgbase}-db-engine-${_relver}-${_snapdate}.tar.gz"
        "http://www.openprinting.org/download/foomatic/${pkgbase}-db-${_relver}-${_snapdate}.tar.xz"
        "http://www.openprinting.org/download/foomatic/${pkgbase}-db-nonfree-${_snapdate}.tar.gz")
url="http://www.linuxprinting.org/foomatic.html"
options=('!emptydirs')
md5sums=('9692ec892f73160885c5da6d71db4dfd'
         'b6cf3456db861b84f2ee191e88607eb0'
         'c33e7804dfa33b769ed249a9e2f5af77')

package_foomatic-db() {

  pkgdesc="Foomatic - The collected knowledge about printers, drivers, and driver options in XML files, used by foomatic-db-engine to generate PPD files."
  arch=('any')
  license=('GPL' 'custom')
  depends=('perl' 'libxml2')

  cd "${srcdir}/${pkgname}-${_snapdate}"
  ./configure --prefix=/usr
  make DESTDIR="${pkgdir}" install 
  install -v -Dm0644 "${srcdir}/${pkgname}-${_snapdate}/COPYING" "${pkgdir}/usr/share/licenses/${pkgname}/COPYING"
}

package_foomatic-db-engine() {

  pkgdesc="Foomatic - Foomatic's database engine generates PPD files from the data in Foomatic's XML database. It also contains scripts to directly generate print queues and handle jobs."
  arch=('x86_64')
  license=('GPL')
  depends=('perl' 'libxml2' 'cups-filters' 'bash')

  cd "${srcdir}/foomatic-db-engine-${_relver}-${_snapdate}"
  ./configure --prefix=/usr --libdir=/usr/lib
  make 
  eval `perl -V:archname`
  make DESTDIR=${pkgdir} \
       INSTALLARCHLIB=/usr/lib/perl5/vendor_perl/ \
       INSTALLSITELIB=/usr/lib/perl5/vendor_perl/ \
       INSTALLSITEARCH=/usr/lib/perl5/vendor_perl/ install 
  /usr/bin/find ${pkgdir} -name '.packlist' -delete
  # fix permissions
  chmod 755 ${pkgdir}/usr/lib{,/perl5,/perl5/vendor_perl}
}

package_foomatic-db-nonfree() {

  pkgdesc="Foomatic - database extension consisting of manufacturer-supplied PPD files released under non-free licenses"
  arch=('any')
  license=('custom')
  depends=('perl' 'libxml2' "foomatic-db-engine" 'foomatic-db')

  cd "${srcdir}/foomatic-db-nonfree-${_snapdate}"
  ./configure --prefix=/usr
  make DESTDIR="${pkgdir}" install 
  install -Dm644 COPYING "${pkgdir}/usr/share/licenses/foomatic-db-nonfree/COPYING"
}