# Part of the Xorg group
# Maintainer: Neophytos Kolokotronis <tetris4@gmail.com>

pkgname=libxcb
pkgver=1.9.3
pkgrel=1
pkgdesc="X11 client-side library"
arch=(x86_64)
url="http://xcb.freedesktop.org/"
depends=('xcb-proto' 'libxdmcp' 'libxau')
makedepends=('pkgconfig' 'libxslt' 'python')
options=('!libtool')
license=('custom')
source=(${url}/dist/${pkgname}-${pkgver}.tar.bz2
        libxcb-1.1-no-pthread-stubs.patch)
sha1sums=('28076500e2ca05e5887c7ed231ba305a85e8bd0b'
          '93330bdcf29a9386b4222e2f0c3cea3add93f5c0')

prepare() { 
  cd "${srcdir}/${pkgname}-${pkgver}"
  patch -Np1 -i "${srcdir}/libxcb-1.1-no-pthread-stubs.patch"
}

build() {
  cd "${srcdir}/${pkgname}-${pkgver}"
  PYTHON=/usr/bin/python2 ./autogen.sh --prefix=/usr --enable-xinput --enable-xkb
  make
}

package () {
  cd "${srcdir}/${pkgname}-${pkgver}"
  make DESTDIR="${pkgdir}" install
  install -m755 -d "${pkgdir}/usr/share/licenses/${pkgname}"
  install -m644 COPYING "${pkgdir}/usr/share/licenses/${pkgname}/"
}